actor PlasmaTridentWep_NormalBar : NormalBar{args 202,110}
actor PlasmaTridentWep : BaseMM8BDMWep
{
Weapon.AmmoUse 3
Weapon.AmmoGive 27
Weapon.SlotNumber 2
Inventory.Pickupmessage "$PU_PLASMATRIDENT"
Obituary "$OB_PLASMATRIDENT"
Tag "$TAG_PLASMATRIDENT"
weapon.ammotype "PlasmaTridentAmmo"
inventory.icon "PTRDICON"
States
{
SpawnLoop:
PTRD Z -1
loop
Ready:
PTRD A 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_PLASMATRIDENT)
PTRD A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
PTRD A 0 
goto DeselectSwap
Select:
PTRD A 0 
goto SelectSwap
Fire:
PTRD A 0 A_JumpIfNoAmmo("NoAmmo")
PTRD A 0 A_PlaySound("weapon/mbuster","Weapon")
PTRD A 0 A_PlaySound("weapon/lasertrident","Item")
PTRD A 0 A_FireCustomMissile("PlasmaTrident",0,1,8,-8)
PTRD BC 3
PTRD A 10
PTRD A 0 A_Refire
Goto Ready+1
NoAmmo:
PTRD A 1 ACS_NamedExecuteAlways("core_noammo",0)
Goto Ready+1
}
}

actor PlasmaTridentAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 27
+INVENTORY.IGNORESKILL
}

actor PlasmaTrident : ProjSpawnFuncActor
{
obituary "$OB_PLASMATRIDENT"
translation "68:72=110:110", "215:228=107:107"
+RIPPER
+THRUSPECIES +CANTSEEK
+SEEKERMISSILE
+SCREENSEEKER
+DONTBLAST
+DONTREFLECT
+BRIGHT
+MISSILE +NOGRAVITY
var int user_TranslateWhiteColors;
var int user_NoOwnerDamage;
+USEDAMAGEEVENTSCRIPT
Speed 20
Damage (CallACS("vile_cbm_damage",18))
Radius 16
Height 20
Scale 2.5
damagetype "PlasmaTrident"
reactiontime 20
States
{
Spawn:
TNT1 A 4
TNT1 A 0 A_ScaleVelocity(1.25)
LTRI C 3
LTRI B 0 A_ScaleVelocity(1.25)
SpawnLoop:
LTRI B 0 A_JumpIfTracerCloser(48,"CloseEnough")
LTRI B 0 A_PlaySoundEx("weapon/blackholestart","Weapon")
LTRI BBB 1 A_SeekerMissile (4, 7, SMF_LOOK|SMF_PRECISE|SMF_CURSPEED, 75, 100)
LTRI C 0 A_JumpIfTracerCloser(48,"CloseEnough")
LTRI CCC 1 A_SeekerMissile (4, 7, SMF_LOOK|SMF_PRECISE|SMF_CURSPEED, 75, 100)
LTRI C 0 A_Countdown
loop
CloseEnough:
LTRI BC 3
LTRI BC 2
goto SpawnLoop
Death:
MMFX B 0 A_PlaySound("misc/metdie")
MMFX B 0 A_Fall
MMFX BCDE 2 A_ChangeFlag("NOGRAVITY",1)
stop
}
}

actor PlasmaTridentProtect : PowerProtection
{Damagefactor "PlasmaTrident", 0.0 Powerup.Duration 8}