actor WarSwordWep_NormalBar : NormalBar{args 214,220}
actor WarSwordWep : BaseMM8BDMWep
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 4
Inventory.Pickupmessage "$PU_WARSWORD"
Obituary "$OB_WARSWORD"
Tag "$TAG_WARSWORD"
weapon.ammotype "WarSwordAmmo"
inventory.icon "WRSWICON"
+WEAPON.NOAUTOAIM
States
{
SpawnLoop:
WRSW Z 1
loop
Ready:
WRSD A 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_WARSWORD)
WRSD A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
WRSD A 0 
goto DeselectSwap
Select:
WRSD A 0 
goto SelectSwap
AltFireWait:
WRSD A 1 A_RailWait
WRSD A 0 A_Refire
Goto Ready+1
Fire:
Fire1:
WRSD A 0 A_JumpIfNoAmmo("NoAmmo")
WRSD A 0 A_TakeInventory("WarSwordAmmo",2,TIF_NOTAKEINFINITE)
//WRSD A 0 A_PlaySoundEx("misc/kingswing","Weapon")
WRSD A 0 A_PlaySoundEx("weapon/warsword1","Weapon")
WRSD B 2
WRSD C 1 
WRSD D 1 
WRSD A 0 A_PlaySoundEx("weapon/warsword2","SoundSlot7")
WSRD A 0 A_FireCustomMissile("WarSword",0,0,0,0,0,0)
WRSD E 1 A_FireCustomMissile("WarSword2",0,0,0,0,0,0)
WRSD F 1
TNT1 A 11
WRSD GH 2
WRSD A 5
WRSD A 0 A_Refire
Goto Ready+1
NoAmmo:
WRSD A 1 ACS_NamedExecuteAlways("core_noammo",0)
Goto Ready+1
}
}

actor WarSwordAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor WarSword : BasicProjectile
{
PROJECTILE
+RIPPER
+BRIGHT
damage (CallACS("vile_cbm_damage",5-pitch))
height 32
radius 32
Speed 33
scale 2.5
reactiontime 1
Obituary "$OB_WARSWORD"
damagetype "WarSword1"
states
{
Spawn:
TNT1 A 0
WASW A 0 A_SetPitch(0)
WASW AAAA 1 A_ScaleVelocity(0.9)
WASW A 0 A_SetPitch(2)
WASW AAAAAA 1 A_ScaleVelocity(0.9)
Dead:
WASW A 1 A_Fadeout(0.1)
loop
XDeath:
TNT1 A 0
stop
}
}

actor WarSword2 : BasicProjectile
{
PROJECTILE
+BRIGHT
damage (CallACS("vile_cbm_damage",24))
height 8
radius 8
Speed 44
scale 2.5
reactiontime 1
Obituary "$OB_WARSWORD"
damagetype "WarSword2"
states
{
Spawn:
TNT1 A 0
WASW BBBBBBBBBBBBB 1 A_ScaleVelocity(0.95)
//Death:
Dead:
WASW B 0 A_SetScale(scalex - 0.25,scaley + 0.15)
WASW B 1 A_Fadeout(0.1)
loop
XDeath:
TNT1 A 0
stop
}
}
actor WarSwordProtect : PowerProtection
{Powerup.duration 2 Damagefactor "WarSword1", 0.3}

actor WarSwordKnockback : Vile_KnockbackHelper
{
Mass 3
Accuracy 0
}

actor WarSwordKnockback2 : Vile_KnockbackHelper
{
Mass 7
Accuracy 0
}
