Actor SpinningTopWep_V_NormalBar : NormalBar{Args 49, 93}
actor SpinningTopWep_V : BaseMM8BDMWep
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 3
Inventory.Pickupmessage "$PU_SPINNINGTOP"
Obituary "$OB_SPINNINGTOP"
Tag "$TAG_SPINNINGTOP"
weapon.ammotype "SpinningTopAmmo_V"
inventory.icon "SNTPICON"
States
{
SpawnLoop:
SNTP A 1
loop
ReadyC: Goto Ready+1
Ready:
SNTP B 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_SPINNINGTOP)
SNTP B 0 A_JumpIfNoAmmo("ReadyNoAmmo")
SNTP L 1 A_WeaponReady
Goto Ready+2
ReadyNoAmmo:
SNTP B 1 A_WeaponReady
SNTP B 0 A_JumpIfNoAmmo("ReadyNoAmmo")
Goto Ready+1
Deselect:
SNTP B 0
goto DeselectSwap
Select:
SNTP B 0
goto SelectSwap
Fire:
SNTP B 0 A_JumpIfNoAmmo("NoAmmo")
SNTP B 0 A_PlaySoundEx("weapon/spinningtop","Weapon")
SNTP B 0 A_FireCustomMissile("SpinningTop_V",0,1,8,0)
SNTP CDEFGH 2
SNTP H 1 Offset(0,42)
SNTP B 2 A_WeaponReady(14)
SNTP B 0 A_Refire
Goto Ready+1
NoAmmo:
SNTP B 1 ACS_NamedExecuteAlways("core_noammo", 0)
Goto ReadyNoAmmo
}
}

actor SpinningTopAmmo_V : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor SpinningTop_V : BasicBouncer
{
PROJECTILE
Speed 30
Damage (CallACS("vile_cbm_damage",18))
damagetype "SpinningTop_V"
Obituary "$OB_SPINNINGTOP"
Radius 13
Height 13
scale 2.5
-NOGRAVITY
+NOEXPLODEFLOOR
+HEXENBOUNCE
ReactionTime 7
States
{
Spawn:
TNT1 A 0
SNTP IJK 3
SNTP A 0 A_Countdown
goto Spawn+1
Death:
TNT1 A 0 A_SpawnItemEx("ExplosionEffect1", 0, 0, 0, 0, 0, 0, 0, SXF_WEPFXCOLOR)
stop
}
}