actor WasteLobberWep_NormalBar : NormalBar{args 229,221}
actor WasteLobberWep : BaseMM8BDMWep
{
Weapon.AmmoUse 3
Weapon.AmmoGive 27
Weapon.SlotNumber 2
Inventory.Pickupmessage "$PU_WASTELOBBER"
Obituary "$OB_WASTELOBBER"
Tag "$TAG_WASTELOBBER"
weapon.ammotype "WasteLobberAmmo"
inventory.icon "WLBRICON"
States
{
SpawnLoop:
WLBR Z -1
loop
Ready:
WLBH A 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_WASTELOBBER)
WLBH A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
WLBH A 0 
goto DeselectSwap
Select:
WLBH A 0 
goto SelectSwap
Fire:
WLBH A 0 A_JumpIfNoAmmo("NoAmmo")
WLBH A 0 A_PlaySoundEx("misc/sharktorpedo","Weapon")
WLBH A 0 A_JumpIfInventory("WasteLobberAmmo",19,"Fire1")
WLBH A 0 A_JumpIfInventory("WasteLobberAmmo",10,"Fire2")
goto Fire3
Fire1:
WLBH G 0 A_FireCustomMissile("WasteLobberBlob",0,1,8,0,0)
WLBH GG 0 A_FireCustomMissile("WasteLobberBlob",frandom(-8,8),0,8,0,0,frandom(-4,12))
goto FireEnd
Fire2:
WLBH G 0 A_FireCustomMissile("WasteLobberBlob2",0,1,8,0,0)
WLBH GG 0 A_FireCustomMissile("WasteLobberBlob2",frandom(-8,8),0,8,0,0,frandom(-4,12))
goto FireEnd
Fire3:
WLBH G 0 A_FireCustomMissile("WasteLobberBlob3",0,1,8,0,0)
WLBH GG 0 A_FireCustomMissile("WasteLobberBlob3",frandom(-8,8),0,8,0,0,frandom(-4,12))
goto FireEnd
FireEnd:
WLBH BCD 2
WLBH EFG 2
TNT1 A 6
WLBH A 2 Offset(-4,69)
WLBH A 2 Offset(-2,48)
WLBH A 2
WLBH A 0 A_Refire
Goto Ready+1
NoAmmo:
WLBH A 1 ACS_NamedExecuteAlways("core_noammo",0)
Goto Ready+1
}
}

actor WasteLobberAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 27
+INVENTORY.IGNORESKILL
}

actor WasteLobberBlob : BasicProjectile
{
Obituary "$OB_WASTELOBBER"
Translation "192:192=229:229", "198:198=221:221"
PROJECTILE
damagetype "WasteLobber"
+NOEXPLODEFLOOR
-NOGRAVITY
+HEXENBOUNCE
+BOUNCEONWALLS
+BOUNCEONFLOORS
+BOUNCEONCEILINGS
+CANBOUNCEWATER
+NOEXPLODEFLOOR
BounceFactor 1.0
WallBounceFactor 1.0
bouncecount 8
Damage (CallACS("vile_cbm_damage",10))
radius 13
height 13
speed 24
scale 2.5
seesound "misc/piratebubble"
States
{
Spawn:
TNT1 A 0 ThrustThingZ(0,30,0,1)
TNT1 A 0
WLBR EFGF 2
goto Spawn+1
Death:
TNT1 A 0 A_PlaySoundEx("misc/piratebubble","Weapon")
TNT1 A 0 A_SpawnItemEx("ExplosionEffect1")
TNT1 ABCD 4
stop
}
}

actor WasteLobberBlob2 : WasteLobberBlob {speed 15}
actor WasteLobberBlob3 : WasteLobberBlob {speed 8}