actor DoubleSpookWep_NormalBar : NormalBar{args 216, 94}
actor DoubleSpookWep : BaseMM8BDMWep
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 4
Inventory.Pickupmessage "$PU_DOUBLESPOOK"
Obituary "$OB_DOUBLESPOOK"
Tag "$TAG_DOUBLESPOOK"
weapon.ammotype "DoubleSpookAmmo"
inventory.icon "DSPKICON"
States
{
SpawnLoop:
DSPK Z 1
loop
Ready:
DSPK A 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_DOUBLESPOOK)
DSPK A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
DSPK A 0
goto DeselectSwap
Select:
DSPK A 0
goto SelectSwap
Fire:
DSPK B 0 A_JumpIfNoAmmo("NoAmmo")
DSPK A 0 A_PlaySoundEx("weapon/deepdiggerthrow","Weapon")
DSPK B 0 A_FireCustomMissile("DoubleSpook",0,1,8,0)
DSPK CDEFGH 3
DSPK A 3 Offset(0,42)
DSPK A 3 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
DSPK A 0 
goto Ready+1
NoAmmo:
DSPK A 1 ACS_NamedExecute("core_noammo",0)
goto Ready+1

}
}

actor DoubleSpookAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor DoubleSpook : BasicProjectile
{
PROJECTILE
Radius 16
Height 24
Scale 2.5
Damage (CallACS("vile_cbm_damage",37))
-NOGRAVITY
+DONTSPLASH
Damagetype "DoubleSpook"
Obituary "$OB_DOUBLESPOOK"
Speed 20
States
{
Spawn:
TNT1 A 0
TNT1 A 1 ThrustThingZ(0, 8, 0, 1)
DSPK I -1
wait
XDeath:
TNT1 A 0 A_ChangeFlag("NOGRAVITY",1)
TNT1 A 0 A_PlaySoundEx("weapons/mm7/dangerwrapexplode", "Weapon")
TNT1 A 0 A_SpawnItemEx("ExplosionEffect2")
stop
Death:
DSPK II 1 A_CheckFloor("Floor")
TNT1 A 0 A_PlaySoundEx("weapons/mm7/dangerwrapexplode", "Weapon")
TNT1 A 0 A_SpawnItemEx("ExplosionEffect2")
TNT1 A 0 A_Explode(CallACS("vile_cbm_damage",37), 72,0,0,24)
stop
Floor:
TNT1 A 0 A_PlaySoundEx("weapons/mm7/dangerwrapexplode", "Weapon")
TNT1 A 0 A_SpawnItemEx("ExplosionEffect2")
TNT1 F 0 A_SpawnItemEx("DoubleSpookPumpkin",0,0,8,21,0,6,8,SXF_NOCHECKPOSITION)
TNT1 F 1 A_SpawnItemEx("DoubleSpookSkull",0,0,8,21,0,6,-8,SXF_NOCHECKPOSITION)
stop
}
}


actor DoubleSpookPumpkin : DoubleSpook
{
Height 16
Damage (CallACS("vile_cbm_damage",29))
States
{
Spawn:
TNT1 A 0
DSPK J 1 ThrustThingZ(0, 14, 0, 1)
DSPK J -1
wait
Death:
TNT1 A 0 A_Explode(CallACS("vile_cbm_damage",29), 64,0,0,24)
goto XDeath
XDeath:
TNT1 A 0 A_ChangeFlag("NOGRAVITY",1)
TNT1 A 0 A_PlaySoundEx("weapons/mm7/dangerwrapexplode", "Weapon")
TNT1 A 0 A_SpawnItemEx("ExplosionEffect2")
stop
}
}


actor DoubleSpookSkull : DoubleSpookPumpkin
{
States
{
Spawn:
TNT1 A 0
DSPK K 1 ThrustThingZ(0, 14, 0, 1)
DSPK K -1
wait
}
}
