actor AssaultCannonWep_NormalBar : NormalBar{args 4,5}
actor AssaultCannonWep : BaseMM8BDMWep
{
Weapon.AmmoUse 10
Weapon.AmmoGive 30
Weapon.SlotNumber 5
Inventory.Pickupmessage "$PU_ASSAULTCANNON"
Obituary "$OB_ASSAULTCANNON"
Tag "$TAG_ASSAULTCANNON"
weapon.ammotype "AssaultCannonAmmo"
inventory.icon "ACNNICON"
States
{
SpawnLoop:
ACNN Z -1
loop
Ready:
ACNN A 0 ACS_NamedExecuteWithResult("core_weaponcolor",COLOR_ASSAULTCANNON)
ACNN A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
ACNN A 0 
goto DeselectSwap
Select:
ACNN A 0 
goto SelectSwap
Fire:
ACNN B 0 A_JumpIfNoAmmo("NoAmmo")
ACNN B 0 A_PlaySound("weapons/mm5/napalmbombfire","Weapon")
ACNN B 0 A_PlaySound("weapons/mm4/drillbombfire","Item")
ACNN B 2 A_SpawnItemEx("ExplosionEffect2",-1,8,32,0,0,0)
ACNN B 1 A_FireCustomMissile("AssaultCannon",0,1,8,0,12)
TNT1 A 0 A_ChangeVelocity(-Cos(pitch)*20, 0, sin(pitch)*10,CVF_RELATIVE)
ACN0 ABCDEF 2
ACN0 G 8
ACN0 HIJJJJJKLMMMMM 3
ACN0 G 0 ACS_NamedExecuteWithResult("core_clientsound", CSND_CRYSTALRELOAD) // A_PlaySoundEx("weapons/mm5/crystaleyereload", "Weapon")
ACN0 NO 3
ACNN A 12
Goto Ready+1
NoAmmo:
ACNN A 0 ACS_NamedExecuteAlways("core_noammo",0)
Goto Ready+1
}
}

actor AssaultCannonAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 30
+INVENTORY.IGNORESKILL
}

actor AssaultCannon : BasicProjectile
{
+FORCEXYBILLBOARD
Height 16
scale 3.25
Radius 16
Damage (CallACS("vile_cbm_damage",40))
speed 30
-NOGRAVITY
gravity 1.0
Damagetype "AssaultCannon"
obituary "$OB_ASSAULTCANNON"
reactiontime 1
states
{
Spawn:
ACNN D 0
Spawn2:
ACNN D 1 A_CheckFloor("Floor")
loop
Floor:
ACNN D 1 A_CountDown
loop
Death:
TNT1 A 0 A_PlaySoundEx("weapon/assaultcannon", "Weapon")
TNT1 A 0 A_Explode(CallACS("vile_cbm_damage",45), 120,0,0,20)
TNT1 AAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("ExplosionEffect3", random(-70,70), random(-70,70), random(-70,70), 0, 0, 0, 0, SXF_WEPFXCOLOR)
TNT1 A 1
TNT1 AAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("ExplosionEffect2", 0, 0, 0, random(-5,5), random(-5,5), random(-5,5), 0, SXF_WEPFXCOLOR)
TNT1 A 35 A_SpawnItemEx("ExplosionEffect4", 0, 0, 0, 0, 0, 0, 0, SXF_WEPFXCOLOR)
stop
}
}
