actor CrossClawWep_NormalBar : NormalBar{args 110,222}
actor CrossClawWep : BaseMM8BDMWep
{
Weapon.AmmoUse 2
Weapon.AmmoGive 48
Weapon.SlotNumber 3
Inventory.Pickupmessage "$PU_CROSSCLAW"
Obituary "$OB_CROSSCLAW"
Tag "$TAG_CROSSCLAW"
weapon.ammotype "CrossClawAmmo"
inventory.icon "CCLWICON"
States
{
SpawnLoop:
CCLW Z -1
loop
Ready:
CCLW A 0 ACS_NamedExecuteWithResult("core_weaponcolor", COLOR_CROSSCLAW)
CCLW A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
CCLW A 0
goto DeselectSwap
Select:
CCLW A 0
goto SelectSwap
Fire:
CCLW A 0 A_JumpIfNoAmmo("NoAmmo")
CCLW A 0 A_PlaySoundEx("Weapon/crossclaw","Weapon")
CCLW A 0 A_FireCustomMissile("CrossClaw1",0,1,-11,-8)
CCLW A 0 A_FireCustomMissile("CrossClawFX",0,0,-2,-1)
CCLW A 0 A_FireCustomMissile("CrossClawFX",0,0,-16,-12)
CCLW A 0 A_Recoil(-7)
CCLW BCDEFG 1 
CCLW H 4
CCLW H 0 A_Refire("Fire2")
Goto Ready+1
Altfire:
CCLW A 0 A_JumpIfInventory("Vile_ClassAltfire", 1, "ClassAltfire")
CCLW A 0 A_JumpIf(CallACS("Vile_class_altfire"), "ClassAltfire")
CCLW A 1 A_JumpIfInventory("MM8BDMPlayer", 1, "Fire2")
wait
ClassAltfire:
CCLW A 0 
goto Super::Altfire
Fire2:
CCLW A 0 A_JumpIfNoAmmo("NoAmmo")
CCLW A 0 A_PlaySoundEx("Weapon/crossclaw","Weapon")
CCLW A 0 A_FireCustomMissile("CrossClaw2",0,1,11,-8)
CCLW A 0 A_FireCustomMissile("CrossClawFX2",0,0,2,-1)
CCLW A 0 A_FireCustomMissile("CrossClawFX2",0,0,16,-12)
CCLW A 0 A_Recoil(-7)
CCLW BCIJKL 1
CCLW M 4
CCLW H 0 A_Refire("Fire")
Goto Ready+1
NoAmmo:
CCLW A 1 ACS_NamedExecuteAlways("core_noammo",0)
Goto Ready+1
}
}

actor CrossClawAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 48
+INVENTORY.IGNORESKILL
}

actor CrossClaw1 : BasicProjectile
{
+RIPPER
Radius 24
Height 24
damage (CallACS("vile_cbm_damage", 8))
damagetype "CrossClaw"
Obituary "$OB_CROSSCLAW"
speed 44
+HEXENBOUNCE
bouncefactor 0.3
wallbouncefactor 0.3
var int user_PierceRipper;
States
{
Spawn:
CCLW N 0
CCLW N 0 A_GiveInventory("PierceRipperLimit", 3)
CCLW NOOPP 1
CCLW P 0 A_ScaleVelocity(0.65)
CCLW QQRST 1
stop
Death:
TNT1 A 1
stop
}
}

actor CrossClaw2 : CrossClaw1
{
xscale -2.5
}

actor CrossClawFX : CrossClaw1
{
speed 40
damage (0)
scale 1.75
}
actor CrossClawFX2 : CrossClawFX
{
xscale -1.75
}