actor RisingSunWep_NormalBar : NormalBar {args 102, 181}

actor RisingSunWep : BaseMM8BDMWep
{
    //$Category RNC-Weapons
    //$Title Rising Sun
    //$Sprite RNCWD0
    Weapon.AmmoUse 1
    Weapon.AmmoGive 28
    Weapon.SlotNumber 2
    Tag "$TAG_RISINGSUN"
    Obituary "$OB_RISINGSUN"
    Inventory.Pickupmessage "$PU_RISINGSUN"
    weapon.ammotype "RisingSunAmmo"
    inventory.icon "RNCWP4"
    States
    {
        SpawnLoop:
            RNCW D -1
            loop

        Ready:
            NCH1 W 0 ACS_NamedExecuteWithResult("core_weaponcolor",CLR_RISINGSUN)
            NCH1 W 0 A_JumpIfNoAmmo(2)
            NCH1 W 1 A_WeaponReady
            goto Ready+1
            NCH2 G 1 A_WeaponReady
            goto Ready+1

        Deselect:
            NCH1 W 0
            goto DeselectSwap
        Select:
            NCH1 W 0
            goto SelectSwap

        Fire:
            NCH1 W 0 A_JumpIfNoAmmo("NoAmmo")
            NCH1 W 0 A_PlaySoundEx("weapon/metalblade","Weapon")
            NCH1 W 0 A_FireCustomMissile("RisingSun",0,1,8,0)
            NCH1 XYZ 2
            NCH2 AB 2
            TNT1 A 3
            TNT1 A 0 A_JumpIfNoAmmo(4)
            NCH2 CD 2
            NCH2 D 0 A_Refire
            goto Ready+1
            NCH2 EF 2
            goto Ready+1
            
        NoAmmo:
            NCH2 G 1 ACS_NamedExecute("core_noammo",0)
            goto Ready+1
    }
}

actor RisingSunAmmo : Ammo {inventory.amount 1 inventory.maxamount 28}

actor RisingSun : BasicProjectile
{
    +RIPPER
    +DONTBLAST
    damagetype "RisingSun"
    Obituary "$OB_RISINGSUN"
    damage (CallACS("rnc_cbm_damage",24))
    Speed 64
    Radius 3
    Height 4
    var int user_TranslateWhiteColors;
    States
    {
        Spawn:
            RNCP LM 3
            loop
    }
}