//
//doomednums used are 12801-12899
//my numbers. you CANT HAVE THEM >:(

//General ======================================================================

actor PeggBoostPadFX 12822
{
//$Category Pegg
+NOINTERACTION
height 1
radius 16
scale 0.5
states
{
	Spawn:
	TNT1 A 1
	TNT1 A 0 A_SpawnItemEx("PeggBoostParticle",56,0,8,0,0,12,args[0])
	TNT1 A 0 A_SpawnItemEx("PeggBoostParticle",-56,0,8,0,0,12,args[0])
	TNT1 A 0 A_SetArg(0,args[0]+15)
	loop
}
}

actor PeggBoostParticle
{
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
scale 1.0
renderstyle stencil
stencilcolor green
reactiontime 7
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEX("PeggBoostParticle2",0,0,-8)
MMFX D 2 A_FadeOut(0.15)
TNT1 A 0 A_CountDown
loop
}
}

actor PeggBoostParticle2 : PeggBoostParticle
{
States
{
Spawn:
TNT1 A 0
MMFX EEEE 2 A_FadeOut(0.25)
stop
}
}


//PEGG01 - Pretentious Genesis =================================================

actor GenesisSkyboxEffect 12811
{
//$Category Pegg
+NOINTERACTION
height 1
radius 1
scale 0.5
states
{
	Spawn:
	TNT1 A 1 A_SpawnItemEx("GenesisSkyboxFX_B", random(-80,80), random(-80,80), 0, 0, 0, -4)
	loop
}
}

actor GenesisSkyboxFX_B : GravityParticleBlue
{
translation "192:192=3:3", "198:198=89:89", "4:4=0:0"
states
{
Spawn:
GRAP ABCD 12
stop
}
}

actor GenesisSkyboxEffect2 : GenesisSkyboxEffect 12812
{
//$Category Pegg
States
{
	Spawn:
	TNT1 A 1 A_SpawnItemEx("GenesisSkyboxFX_W", random(-80,80), random(-80,80), 0, 0, 0, 4)
	loop
}
}

actor GenesisSkyboxFX_W : GenesisSkyboxFX_B
{
translation "192:192=80:80", "198:198=89:89"
}

actor GenesisGravityArrow : GravityArrowSolo 12813
{
//$Category Pegg
translation "106:106=227:227"
}

actor GenesisTorch_W : KnightTorch 12814
{
//$Category Pegg
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEX("GenesisTorchLight_W",0,0,32,0,0,0,0,0)
The:
P_1A A 1
loop 
}
}

actor GenesisTorch_B : GenesisTorch_W 12815
{
//$Category Pegg
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEX("GenesisTorchLight_B",0,0,32,0,0,0,0,0)
The:
P_1B A 1
loop 
}
}

actor GenesisTorchLight_W
{
+FORCEXYBILLBOARD
+FLOATBOB
+NOGRAVITY
height 1
radius 1
scale 2.0
States
{
Spawn:
P_1A BCDEFGHI 4
loop
}
}

actor GenesisTorchLight_B : GenesisTorchLight_W
{
States
{
Spawn:
P_1B BCDEFGHI 4
loop
}
}

actor GenesisCrystalJoe : CrystalJoe 12816
{
//$Category Pegg
translation "103:103=67:67", "0:0=95:95"
}

actor GenesisSkeletonJoe : SkeletonJoe 12817
{
//$Category Pegg
translation "106:106=195:195", "4:4=95:95"
}

//PEGG02 - Diesel Industries ===================================================

actor RBBSpike 12810
{
//$Category Pegg
+CLIENTSIDEONLY
scale 2.5
+NOINTERACTION
-SOLID
States
{
Spawn:
P_2A A -1
stop
}
}

//PEGG03 - Sabe A Naranjas =====================================================

actor NRJBush 12808
{
//$Category Pegg
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
scale 2.5
States
{
Spawn:
P_3A A -1
stop
}
}

actor NRJSmokeSpawner 12809
{
//$Category Pegg
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
states
{
Spawn:
TNT1 A 0
TNT1 A 25 A_SpawnItemEX("NRJSmoke",random(-4,4),random(-4,4),0,random(-1,1),random(-1,1),3,random(0,359),0)
loop
}
}

actor NRJSmoke
{
translation "198:198=214:214", "192:192=4:4"
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
scale 2.0
States
{
Spawn:
TNT1 A 0
KMUM HGF 2
KMUM EDEDEDEDEDED 4
KMUM EDEDEDEDED 4 A_Fadeout(0.1)
stop
}
}

//PEGG04 - Fresh Lettuce =======================================================
//No custom actors! Awesome

//PEGG05 - Dark Castle =========================================================

actor DCShotzo 12801 //sprites yoinked from maxine's orange ocean map
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
height 32
radius 16
States
{
Spawn:
P_5A A -1 //it was funnier when it was O instead of A
stop
}
}

actor DCBlocky 12802
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
height 48
radius 32
States
{
Spawn:
P_5A BCDDC 6
loop
}
}

actor DCButch 12803
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
height 32
radius 16
States
{
Spawn:
P_5A E -1 //the axe rotation sucks, but i don't care!
stop
}
}

actor DCBlade 12804
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
height 32
radius 16
States
{
Spawn:
P_5A F -1 
stop
}
}

actor DCGordoMove 12805
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
+CLIENTSIDEONLY
height 32
radius 16
States
{
Spawn:
P_5A G 0
TNT1 A 0 A_ChangeVelocity(0,0,3,1)
CeilingCheck:
P_5A GGGGGGHHHHHH 1 A_CheckCeiling("CeilingHit")
Loop
CeilingHit:
TNT1 A 0 A_ChangeVelocity(0,0,-3,1)
FloorCheck:
P_5A GGGGGGHHHHHH 1 A_CheckFloor("Spawn")
Loop
}
}

actor DCGordoStationary 12806
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
+CLIENTSIDEONLY
height 32
radius 16
States
{
Spawn:
P_5A GH 6
Loop
}
}

actor DCPrisoner 12807
{
//$Category Pegg
scale 2.5
+NOGRAVITY
+SOLID
height 32
radius 16
States
{
Spawn:
P_5A I -1
stop
}
}

//PEGG06 - Hello Again =========================================================

actor PeggLabyrinthTree1 12818
{
//$Category Pegg
+CLIENTSIDEONLY
scale 2.5
States
{
Spawn:
P_6A A -1
stop
}
}

actor PeggLabyrinthTree2 12819
{
//$Category Pegg
+CLIENTSIDEONLY
scale 2.5
States
{
Spawn:
P_6A B -1
stop
}
}

actor PeggLabyrinthTorch : Torch 12820
{
//$Category Pegg
translation "42:42=164:164", "225:225=160:160", "74:74=185:185", "207:207=227:227", "103:103=228:228"
}

actor PLZMistSpawner 12821
{
//$Category Pegg
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEX("PLZFauxSplashSpawner")
TNT1 A 0 A_SpawnItemEX("PLZMistAmbientNoise_H")
TrueLoop:
TNT1 A 5 A_SpawnItemEX("PLZMist",-10,random(-4,4),0,2,random(-1,1),random(0,1),0,0)
TNT1 AA 0 A_SpawnItemEX("PLZDroplet",0,random(-4,4),0,random(5,10),random(-4,4),random(5,10),0,0)
loop
}
}

actor PLZMist
{
translation "198:198=196:196", "192:192=196:196"
+CLIENTSIDEONLY
+FORCEXYBILLBOARD
+NOINTERACTION
+NOGRAVITY
-SOLID
scale 2.0
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SetScale(0.5,1.0)
TNT1 A 0 A_Jump(128,"2")
W_RC PPPPPPPPPP 4 A_Fadeout(0.1)
stop
2:
TNT1 A 0
W_RC OOOOOOOOOO 4 A_Fadeout(0.1)
stop
}
}

actor PLZDroplet
{
+CLIENTSIDEONLY
+FORCEXYBILLBOARD 
+DONTSPLASH
-NOGRAVITY
-SOLID
scale 1.0
States
{
Spawn:
TNT1 A 0
PIXL A 15
stop
}
}

actor PLZFauxSplashSpawner 
{
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEX("PLZFauxSplash",-24,random(-24,24),0,0,0,0,0,0)
TNT1 A 10 A_SpawnItemEX("PLZFauxSplash",random(-24,24),random(-24,24),0,0,0,0,0,0)
loop
}
}

actor PLZFauxSplash
{
+CLIENTSIDEONLY
+NOINTERACTION
-NOGRAVITY
-SOLID
scale 2.5
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_Jump(32,"2")
TNT1 A 0 A_Jump(32,"3")
TNT1 A 0 A_Jump(32,"4")
DOLP BCDE 5
Stop
2:
TNT1 A 0
DOLP BCDE 2
stop
3:
TNT1 A 0
DOLP BCDE 3
stop
4:
TNT1 A 0
DOLP BCDE 4
stop
}
}

actor PLZMistAmbientNoise_H
{
+CLIENTSIDEONLY
+FORCEXYBILLBOARD
+NOINTERACTION
+NOGRAVITY
-SOLID
Scale 1.0
States
{
Spawn:
TNT1 A 0
TNT1 A 20 A_PlaySound("misc/fullenglish",7,0.4,0,ATTN_STATIC)
loop
}
}

//PEGG07 - Rootin-Tootin, Scorchin-Shootin =========================================================

actor PeggCowboysPropBase
{
scale 2.5
+CLIENTSIDEONLY
+NOINTERACTION
+NOGRAVITY
-SOLID
height 16
radius 16
States
{
Spawn:
TNT1 A -1
wait
}
}

actor PCB_Beer0 : PeggCowboysPropbase
{
States
{
Spawn:
P_7A A -1
wait
}
}

actor PCB_Beer1 : PeggCowboysPropbase
{
States
{
Spawn:
P_7B A -1
wait
}
}

actor PCB_Beer2 : PeggCowboysPropbase
{
States
{
Spawn:
P_7C A -1
wait
}
}

actor PCB_Beer3 : PeggCowboysPropbase
{
States
{
Spawn:
P_7D A -1
wait
}
}

actor PCB_Stool : PeggCowboysPropbase
{
States
{
Spawn:
P_7E A -1
wait
}
}

//PEGG08 - Era of a Modern Power =========================================================

actor SubterraneanSun 12823
{
//$Category Pegg
+CLIENTSIDEONLY
scale 1.8
+NOINTERACTION
+FORCEXYBILLBOARD
+NOGRAVITY
-SOLID
renderstyle add
radius 128
States
{
Spawn:
P_8A A 1
P_8A A 0 A_SpawnItemEX("SubterraneanSunAura",0,0,0,0,0,0,0,0)
go:
P_8A ABCD 5 A_SpawnItemEx("PeggNuclearFlare", random(-64,64), random(-64,64), random(-64,64), random(-2,2), random(-2,2), random(-2,2))
loop
}
}

actor SubterraneanSunAura 
{
//$Category Pegg
+CLIENTSIDEONLY
scale 2.0
+NOINTERACTION
+FORCEXYBILLBOARD
+NOGRAVITY
-SOLID
renderstyle add
alpha 0.5
States
{
Spawn:
P_8A A 8 
P_8A B 8 A_SetScale(2.05,2.05)
P_8A C 8 A_SetScale(2.1,2.1)
P_8A D 8 A_SetScale(2.2,2.2)
P_8A A 8 A_SetScale(2.3,2.3)
P_8A B 8 
P_8A C 8 
P_8A D 8 
P_8A A 8 A_SetScale(2.2,2.2)
P_8A B 8 A_SetScale(2.1,2.1)
P_8A C 8 A_SetScale(2.05,2.05)
P_8A D 8 A_SetScale(2.0,2.0)
loop
}
}

actor PeggNuclearFlareSpawner 12824
{
//$Category Pegg
+NOINTERACTION
height 1
radius 1
scale 0.5
states
{
	Spawn:
	TNT1 A 5 A_SpawnItemEx("PeggNuclearFlare", random(-1024,1024), random(-1024,1024), 0, 0, 0, 4)
	loop
}
}

actor PeggNuclearFlare
{
+CLIENTSIDEONLY
scale 1.5
+NOINTERACTION
+FORCEXYBILLBOARD
+NOGRAVITY
-SOLID
renderstyle add
alpha 0.5
states
{
Spawn:
P_8B EDCDEEDCDEEDCDEEDDCC 6
stop
}
}