actor CircuitBreakerWep_NormalBar : NormalBar { args 104, 128 }

actor CircuitBreakerWep : BaseMM8BDMWep
{
	//$Category MM8BDM-Weapons
	//$Title Circuit Breaker
	Weapon.AmmoUse 2
	Weapon.AmmoGive 28
	Weapon.SlotNumber 3
	Inventory.Pickupmessage "$PU_CIRCUITBREAKER"
	Obituary "$OB_CIRCUITBREAKER"
	Tag "$TAG_CIRCUITBREAKER"
	weapon.ammotype "CircuitBreakerAmmo"
	inventory.icon "CIBRI"
	States
	{
		SpawnLoop:
			CBRK A -1
			loop
			
		Ready:
			CBRK C 0 ACS_NamedExecuteWithResult("core_weaponcolor",CLR_CIRCUITBREAKER)
			CBRK C 1 A_WeaponReady
			Goto Ready+1
			
		Deselect:
			CBRK C 0
			goto DeselectSwap
		Select:
			CBRK C 0
			goto SelectSwap
			
		Fire:
			CBRK C 0 A_JumpIfNoAmmo("NoAmmo")
			CBRK C 0 A_PlaySoundEx("weapon/circuit","Weapon")
			CBRK DE 2
			CBRK C 0 A_FireCustomMissile("CircuitBreaker",-8,1,8,0)
			CBRK C 0 A_FireCustomMissile("CircuitBreaker",8,0,8,0)
			CBRK F 3
			CBRK ED 1
			CBRK D 0 A_Refire
			Goto Ready+1
			
		NoAmmo:
			CBRK C 1 ACS_NamedExecuteAlways("core_noammo",0)
			Goto Ready+1
	}
}

actor CircuitBreakerAmmo : Ammo
{
	inventory.amount 1
	inventory.maxamount 28
	+INVENTORY.IGNORESKILL
}


actor CircuitBreaker : BasicProjectile
{
	Radius 5
	Height 5
	damagetype "CircuitBreaker"
	Obituary "$OB_CIRCUITBREAKER"
	damage (CallACS("mmrf_cbm_damage", 2))
	speed 55
	States
	{
		Spawn:
			CBRK B 1
			loop
		Death:
			NAPA A 0 A_Stop
			NAPA A 0 A_PlaySoundEx("misc/mm3explosion", "Weapon")
			NAPA A 0 A_ChangeFlag("NOGRAVITY",1)
			NAPA D 0 A_Explode(CallACS("mmrf_cbm_damage", 12), 96, 0)
			NAPA FGHIJKLMNOPQRS 2
			stop
	}
}