actor IceLiftWep_NormalBar : NormalBar { args 193, 207 }
actor IceLiftWep : BaseMM8BDMWep
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 3
Inventory.Pickupmessage "$PU_ICELIFT"
Obituary "$OB_ICELIFT"
Tag "$TAG_ICELIFT"
inventory.icon "ICLFICON"
weapon.ammotype "IceLiftAmmo"
States
{
SpawnLoop:
ICLF Z -1 
loop
Ready: 
ICLF A 0 ACS_NamedExecuteWithResult("core_weaponcolor",CLR_ICELIFT)
ICLF A 1 A_WeaponReady
Goto Ready+1
ReadyC: Goto Ready+1
Deselect:
ICLF A 0
goto DeselectSwap
Select:
ICLF A 0
goto SelectSwap
Fire:
ICLF A 0 A_JumpIfNoAmmo("NoAmmo")
ICLF A 0 A_PlaySoundEx("weapons/mmqg/iceliftfire","Weapon")
ICLF A 0 A_FireCustomMissile("IceLift",0,1,8,0)
ICLF BCA 3
ICLF A 6
ICLF A 0 A_Refire
Goto Ready+1
NoAmmo:
ICLF A 1 ACS_NamedExecuteAlways("core_noammo", 0)
Goto Ready+1
}
}

actor IceLiftAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor IceLift : BasicProjectile
{
Damage (CallACS("mmqg_cbm_damage",22))
damagetype "IceLift"
obituary "$OB_ICELIFT"
Height 18
Radius 18
-NOGRAVITY
Speed 30
States
{
Spawn:
ICLF D 0
ICLF D 0 ThrustThingZ(0,12,0,1)
ICLF D 1
Goto Spawn+2
Crash:
ICLF DDDD 0 A_SpawnItemEx("IceLiftFX",0,0,0,random(-10,10),random(-10,10),random(5,10),random(0,359),SXF_WEPFXCOLOR)
TNT1 A 5 A_PlaySoundEx("weapons/mmqg/iceliftshatter", "auto")
stop
Death:
ICLF D 0 A_CheckFloor("Death.Floor")
TNT1 A 1
goto Crash

Death.Floor:
ICLF D 0 A_SpawnItemEx("IceLiftDebris", -3, -8, 12, 27, -1, 0, 0, 0)
ICLF D 0 A_SpawnItemEx("IceLiftDebris", -3, 8, 12, 27, 1, 0, 0, 0)
ICLF D 0 A_SpawnItemEx("IceLiftDebris", 3, -8, 16, 27, -1, 2.5, 0, 0)
ICLF D 0 A_SpawnItemEx("IceLiftDebris", 3, 8, 16, 27, 1, 2.5, 0, 0)
TNT1 A 5 A_PlaySoundEx("weapons/mmqg/iceliftsplit", "auto")
stop
}
}

actor IceLiftDebris : BasicProjectile
{
Damage (CallACS("mmqg_cbm_damage",11))
damagetype "IceLift"
obituary "$OB_ICELIFT"
scale 2.75
Height 11
Radius 11
Speed 20
States
{
Spawn:
ICLF E 1
loop
}
}

actor IceLiftFX : BasicGraphicEffect
{
+HEXENBOUNCE
-NOINTERACTION
-NOGRAVITY
+RIPPER
damage (0)
scale 1.75
States
{
SpawnFrame:
ICLF E 2
TNT1 A 2
ICLF E 2
TNT1 A 2
ICLF E 2
TNT1 A 2
ICLF E 2
TNT1 A 2
ICLF E 2
TNT1 A 2
stop
}
}