actor GEyeJoe // Riot/Crowd control cops
{
	PROJECTILE
	+THRUACTORS
	+FLOORHUGGER
	+ACTIVATEMCROSS
	translation "192:192=71:71", "198:198=199:199"
	Scale 2.5
	Speed 20
	Damage 0
	renderstyle translucent
	Alpha 0.1
	States
	{
	Spawn:
		GIJO B 0
		GIJO DDDDDCCCCC 1 A_FadeIn(0.1)
		GIJO B 0 A_SetTranslucent(1.0, 0)
		goto SpawnLoop
	SpawnLoop:
		GIJO BCDC 5
		GIJO A 0 A_JumpIfInventory("DecayQueue", 1, "SpawnFade")
		loop
	ToArms:
		GIJO F 0 A_ChangeFlag("ACTIVATEMCROSS", false)
		GIJO F 0 A_PlaySoundEx("misc/fakereloadshort", "weapon")
		GIJO F 0 A_SetAngle(180)
		GIJO F 0 A_Stop
		GIJO F 0 A_SpawnItemEx("GEyeShield", 32, 8, 0, momx, momy, momz, 0, SXF_ABSOLUTEMOMENTUM|SXF_TRANSFERTRANSLATION)
		GIJO F 1
		goto ToArms+3
	FromArms:
		GIJO FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 1 A_SpawnItemEx("GEyeShield", 32, 8, 0, momx, momy, momz, 0, SXF_ABSOLUTEMOMENTUM|SXF_TRANSFERTRANSLATION)
		GIJO A 0 A_PlaySoundEx("misc/fakereloadend", "weapon")
		GIJO A 35
		GIJO F 0 A_SetAngle(270)
		GIJO F 0 A_ChangeVelocity(6, 0, 0, CVF_RELATIVE|CVF_REPLACE)
		GIJO C 5
		GIJO F 0 A_ChangeFlag("ACTIVATEMCROSS", true)
		goto SpawnLoop
	SpawnFade:
		GIJO BBBBBCCCCCDDDDDCCCCC 1 A_FadeOut
		loop
	}
}

actor GEyeNoShield : GEyeJoe
{
	States
	{
	Spawn:
		GIJO B 0
		GIJO DDDDDCCCCC 1 A_FadeIn(0.1)
		GIJO B 0 A_SetTranslucent(1.0, 0)
		goto SpawnLoop
	SpawnLoop:
		GIJO BCDC 5
		GIJO A 0 A_JumpIfInventory("DecayQueue", 1, "SpawnFade")
		loop
	ToArms:
		GIJO F 0 A_ChangeFlag("ACTIVATEMCROSS", false)
		GIJO F 0 A_PlaySoundEx("misc/fakereloadshort", "weapon")
		GIJO F 0 A_SetAngle(180)
		GIJO F 0 A_Stop
		GIJO F 1
		wait
	FromArms:
		GIJO A 0 A_PlaySoundEx("misc/fakereloadend", "weapon")
		GIJO A 35
		GIJO F 0 A_SetAngle(270)
		GIJO F 0 A_ChangeVelocity(6, 0, 0, CVF_RELATIVE|CVF_REPLACE)
		GIJO C 5
		GIJO F 0 A_ChangeFlag("ACTIVATEMCROSS", true)
		goto SpawnLoop
	SpawnFade:
		GIJO BBBBBCCCCCDDDDDCCCCC 1 A_FadeOut
		loop
	}
}

actor GEyeShield
{
	+NOINTERACTION
	+NOGRAVITY
	+CLIENTSIDEONLY
	+FORCEXYBILLBOARD
	-SOLID
	scale 2.5
	height 0
	radius 0
	renderstyle translucent
	States
	{
	Spawn:
		GIJO G 0
		GIJO G 1
		stop
	}
}

actor GEyeShieldFade9 : GEyeShield { Alpha 0.9 }
actor GEyeShieldFade8 : GEyeShield { Alpha 0.8 }
actor GEyeShieldFade7 : GEyeShield { Alpha 0.7 }
actor GEyeShieldFade6 : GEyeShield { Alpha 0.6 }
actor GEyeShieldFade5 : GEyeShield { Alpha 0.5 }
actor GEyeShieldFade4 : GEyeShield { Alpha 0.4 }
actor GEyeShieldFade3 : GEyeShield { Alpha 0.3 }
actor GEyeShieldFade2 : GEyeShield { Alpha 0.2 }
actor GEyeShieldFade1 : GEyeShield { Alpha 0.1 }

actor DecayQueue : Once {}
actor KnifeProp : DecayQueue {}

actor PoliceJoe 20411 // Sleeping cop
{
	//$Category DOSReborn-Props
	+SOLID
	translation "192:192=71:71", "198:198=199:199"
	Height 76
	Radius 16
	scale 2.5
	States
	{
	Spawn:
		CPJO A 0
		CPJO A 70
		CPJO B 35
		loop
	}
}

actor KnifeStreetLight 20412
{
	//$NotAngled
	//$Category DOSReborn-Props
	+SOLID
	+FORCEYBILLBOARD
	radius 16
	height 286
	Scale 2.0
	States
	{
	Spawn:
		DKPR A 0
		DKPR A 0 A_SpawnItemEx("KnifeLightGlow", -2, 0, 250)
		DKPR A 1 A_FaceConsolePlayer
		wait
	}
}

actor KnifeMetBush 20413
{
	//$Category DOSReborn-Props
	scale 2.5
	Height 64
	Radius 32
	+FORCEYBILLBOARD
	+SOLID
	translation "4:4=160:160", "116:116=111:111", "123:123=121:121"
	States
	{
	Spawn:
		BSMT A 1
		wait
	}
}

actor KnifeLightGlow
{
	PROJECTILE
	+THRUACTORS
	+NOINTERACTION
	+CLIENTSIDEONLY
	Scale 2.0
	renderstyle translucent
	alpha 0.8
	States
	{
	Spawn:
		DKPR BBBCCCDDDCCC 1 A_Warp(AAPTR_TARGET, -2, 0, 250, 0, 0)
		loop
	}
}

actor TommyJoe : GEyeJoe
{
	Translation "192:192=89:89", "198:198=252:252"
	Alpha 1.0
	States
	{
	Spawn:
		TYJO BCDC 5
		loop
	SpawnWait:
		TYJO F 0 A_ChangeFlag("ACTIVATEMCROSS", false)
		TYJO A 0 A_Stop
		TYJO A 1
		wait
	SpawnLoop:
		TYJO BCDC 5
		loop
	Laugh:
		TYJO AAAAAAAA 2
		TYJO GFGFGFGF 2
		TYJO AAAAAAAA 1 A_SetAngle(angle+22.5)
		TYJO A 0 A_ChangeVelocity(6, 0, 0, CVF_REPLACE|CVF_RELATIVE)
		goto Spawn
	}
}

actor ThugJoe : TommyJoe
{
	Translation "192:192=38:38", "198:198=41:41"
	States
	{
	Spawn:
		TGJO BCDC 5
		loop
	SpawnWait:
		TYJO F 0 A_ChangeFlag("ACTIVATEMCROSS", false)
		TGJO B 0 A_Stop
		TGJO A 1
		wait
	Laugh:
		TGJO AAAAAAAA 2
		TGJO AAAAAAAAAAAAA 2
		TGJO AAAAAAAA 1 A_SetAngle(angle+22.5)
		TGJO A 0 A_ChangeVelocity(6, 0, 0, CVF_REPLACE|CVF_RELATIVE)
		goto Spawn
	}
}

actor KnifeCar 20414
{
	//$Category DOSReborn-Props
	scale 2.0
	Height 128
	Radius 113
	+FORCEYBILLBOARD
	+SOLID
	States
	{
	Spawn:
		DKPR E 1
		wait
	}
}