Actor Succubus : McM_Monster replaces Shotgunguy {
	obituary "%o was charmed by a Succubus."
	Health 75
	Radius 20
	Height 56
	Speed 7
	Mass 100
	PainChance 192
	SEESOUND "succubus/see"
	painsound "succubus/pain"
	deathsound "succubus/die"
	activesound "succubus/act"
	DropItem "Shotgun"
	MONSTER
	+NODROPOFF
	+FLOORCLIP
	Tag "Succubus"
	states {
		Idle:
			SUCC AB 10 A_Look
		loop
		See:
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "FastChase")
			SUCC AB 3 A_Chase
		loop
		FastChase:
			SUCC AB 3 A_Chase
			SUCC B 1 A_FastChase
		Loop
		Missile:
			SUCC G 4 A_FaceTarget
			SUCC I 4
			TNT1 A 0 A_PlaySound("Succubus/Attack")
			TNT1 A 0 A_CustomMissile ("PinkBall", 32, 0, 0)
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "Another")
			SUCC J 5 A_FaceTarget
		Goto See
		Another:
			TNT1 A 0 A_Jump(128, "Skip")
			SUCC J 1
			TNT1 A 0 A_CustomMissile ("PinkBall", 32, 0, -8)
			TNT1 A 0 A_CustomMissile ("PinkBall", 32, 0, 8)
		Skip:
			SUCC J 5 A_FaceTarget
		goto See
		Pain:
			SUCC H 2
			SUCC H 2 A_Pain
			SUCC GGG 2 A_FastChase
		Goto See
		Death:
			SUC1 A 6 A_Scream
			TNT1 A 0 A_NoBlocking
			TNT1 A 0 A_SpawnItemEx("SuccubusDeathFX", 0, 0, 24)
			SUC1 BCG 6
			SUC1 HI 6
			SUC1 K -1
		Stop
		Death.Corpse:
			SUC1 K -1
		Stop
		Raise:
			SUC1 IHGCBA 6
		Goto See
	}
}

Actor PinkBallTrail {
	+NOINTERACTION
	+CLIENTSIDEONLY
	+VISIBILITYPULSE
	RenderStyle Add
	Alpha 0.4
	States {
		Spawn:
			LMP1 ABCD 1
		Stop
	}
}

actor PinkBall {
	radius 4
	height 3
	speed 21
	damage (random(8, 16))
	renderstyle Add
	deathsound "imp/shotx"
	PROJECTILE
	+NODAMAGETHRUST
	states {
		Spawn:
			LMP1 ABCD 2 Bright A_SpawnItem("PinkBallTrail")
		loop
		Death:
			LMP1 EFG 6 bright
		stop
	}
}

Actor SuccubusDeathFX {
	+CLIENTSIDEONLY
	+NOINTERACTION
	RenderStyle Add
	Translation "48:63=%[0.00,0.00,0.00]:[1.06,0.26,1.17]", 
				"64:79=%[0.00,0.00,0.00]:[1.02,0.23,0.97]", 
				"160:167=%[0.00,0.00,0.00]:[1.14,0.15,1.02]", 
				"224:231=%[0.00,0.00,0.00]:[1.65,0.30,1.76]",
				"249:249=%[0.00,0.00,0.00]:[1.52,0.31,1.65]"
	Alpha 1.0
	States {
		Spawn:
			SCFX ABCDEFG 3 Bright A_FadeOut(0.05)
		Stop
	}
}