// QCDE doesn't seem to like inheritance
Actor GraveDigger_Ghost : McM_Monster replaces Spectre {
	Health 185
	PainChance 96
	Speed 16
	Mass 1024
	Radius 30
	Height 56
	MONSTER
	Obituary "%o had their grave dug up by a Gravedigger."
	HitObituary "%o won't have an open casket funeral."
	SeeSound "SoulEater/See"
	AttackSound "Monster/sg2atk"
	PainSound "SoulEater/Pain"
	DeathSound "SoulEater/Die"
	ActiveSound "SoulEater/Act"
	Tag "Gravedigger"
	MaxTargetRange 264
	Scale 1.15
	Translation "Ice"
	Alpha 0.5
	Renderstyle Add
	BloodColor "36 36 99"
	Species "Demon"
	+DONTHARMSPECIES
	+DONTHURTSPECIES
	+GHOST
	States {
		Idle:
			SAR3 A 10 A_Look
			SAR3 A 0 A_SpawnItemEX("GraveDiggerTrailA") 
			SAR3 B 10 A_Look
			SAR3 B 0 A_SpawnItemEX("GraveDiggerTrailB") 
		Loop 
		See:
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "SeeMissile")
			SAR3 AA 2 A_Chase("Melee", "")
			SAR3 A 0 A_SpawnItemEX("GraveDiggerTrailA") 
			SAR3 BB 2 A_Chase("Melee", "")
			SAR3 B 0 A_SpawnItemEX("GraveDiggerTrailB") 
			SAR3 CC 2 A_Chase("Melee", "")
			SAR3 C 0 A_SpawnItemEX("GraveDiggerTrailC") 
			SAR3 DD 2 A_Chase("Melee", "")
			SAR3 D 0 A_SpawnItemEX("GraveDiggerTrailD") 
		Loop
		SeeMissile:
			SAR3 AA 2 A_Chase("Melee", "Missile")
			SAR3 A 0 A_SpawnItemEX("GraveDiggerTrailA") 
			SAR3 BB 2 A_Chase("Melee", "Missile")
			SAR3 B 0 A_SpawnItemEX("GraveDiggerTrailB") 
			SAR3 CC 2 A_Chase("Melee", "Missile")
			SAR3 C 0 A_SpawnItemEX("GraveDiggerTrailC") 
			SAR3 DD 2 A_Chase("Melee", "Missile")
			SAR3 D 0 A_SpawnItemEX("GraveDiggerTrailD") 
		Loop
		Melee:
			SAR3 EF 6 A_FaceTarget
			SAR3 G 6 A_CustomMeleeAttack(random(5, 10) * 4)
		Goto See
		Missile:
			SAR3 GE 5 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav_Icey", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
		Goto See
		Retaliate:
			SAR3 GE 5 A_FaceTarget
			TNT1 A 0  A_CustomMissile("Bloodshot_Icey", 27, 0)
			SAR3 F 5 A_CustomMissile("Bloodshot_Icey", 27, 0, -2)
			TNT1 A 0 A_FaceTarget
			TNT1 A 0  A_CustomMissile("Bloodshot_Icey", 27, 0)
			SAR3 F 5 A_CustomMissile("Bloodshot_Icey", 27, 0, 2)
			SAR3 EG 5
		Goto See
		Pain:
			SAR3 H 2
			SAR3 H 2 A_Pain
			TNT1 A 0 A_Jump(96, "Retaliate")
		Goto See
		Death:
			SAR3 I 8
			SAR3 J 8 A_Scream
			SAR3 K 4
			SAR3 L 4 A_NoBlocking
			SAR3 M 4
			SAR3 N -1
		Stop
		Death.Corpse:
			SAR3 N -1
		Stop
		Raise:
			SAR3 NMLKJI 5
		Goto See
	}
}

Actor Bloodshot_Icey : Bloodshot {
	Translation "Ice"
	Alpha 0.75
	Renderstyle Add
	States {
		Spawn:
			FBLD A 2 Bright A_CStaffMissileSlither
			FBLD A 0 A_SpawnItemEx("Bloodtrail_Icey",0,0,0,0,0,0,128)
			FBLD B 2 Bright A_CStaffMissileSlither
			FBLD B 0 A_SpawnItemEx("Bloodtrail_Icey",0,0,0,0,0,0,128)
		Loop
		Death:
			FBLD CDE 3 Bright
		Stop
	}
}

Actor Bloodshot_Grav_Icey : Bloodshot_Grav {
	Translation "Ice"   
	Alpha 0.75
	Renderstyle Add
	States {
		Spawn:
			TNT1 A 0 NoDelay ThrustThingZ(0, 18, 0, 0)
		SpawnLoop:
			FBLD A 2 Bright A_CStaffMissileSlither
			FBLD A 0 A_SpawnItemEx("Bloodtrail_Icey",0,0,0,0,0,0,128)
			FBLD B 2 Bright A_CStaffMissileSlither
			FBLD B 0 A_SpawnItemEx("Bloodtrail_Icey",0,0,0,0,0,0,128)
		Loop
		Death:
			FBLD CDE 3 Bright
		Stop
	}
}

Actor Bloodtrail_Icey : BloodTrail {
	Alpha 0.75
	Renderstyle Add
	Translation "Ice"
}

ACTOR GraveDiggerTrailA {   
	Radius 1
	Height 1   
	RENDERSTYLE ADD
	Alpha 0.50
	Translation "Ice"
	Scale 1.15
	+FORCEXYBILLBOARD
	+NOINTERACTION
	+CLIENTSIDEONLY
	States {
		Spawn:
			SAR3 A 10  
			SAR3 AAAAAAAAA 3 A_FadeOut(0.05) 
		Stop 
	}
}

ACTOR GraveDiggerTrailB : GraveDiggerTrailA {   
	States {
		Spawn:
			SAR3 B 10  
			SAR3 BBBBBBBBB 3 A_FadeOut(0.05) 
		Stop 
	}
}

ACTOR GraveDiggerTrailC : GraveDiggerTrailA {   
	States {
		Spawn:
			SAR3 C 10  
			SAR3 CCCCCCCCC 3 A_FadeOut(0.05) 
		Stop 
	}
}

ACTOR GraveDiggerTrailD : GraveDiggerTrailA {   
	States{
		Spawn:
			SAR3 D 10  
			SAR3 DDDDDDDDD 3 A_FadeOut(0.05) 
		Stop 
	}
}