Actor GraveDigger : McM_Monster replaces Demon {
	Health 185
	PainChance 96
	Speed 16
	Mass 1024
	Radius 30
	Height 56
	MONSTER
	Obituary "%o had their grave dug up by a Gravedigger."
	HitObituary "%o won't have an open casket funeral."
	SeeSound "SoulEater/See"
	AttackSound "Monster/sg2atk"
	PainSound "SoulEater/Pain"
	DeathSound "SoulEater/Die"
	ActiveSound "SoulEater/Act"
	Tag "Gravedigger"
	MaxTargetRange 264
	Scale 1.15
	Species "Demon"
	+DONTHARMSPECIES
	+DONTHURTSPECIES
	States {
		Idle:
			SAR3 AB 10 A_Look
		Loop
		See:
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "SeeMissile")
			SAR3 AABBCCDD 2 A_Chase("Melee", "")
		Loop
		SeeMissile:
			SAR3 AABBCCDD 2 A_Chase("Melee", "Missile")
		Goto See
		Melee:
			SAR3 EF 6 A_FaceTarget
			SAR3 G 6 A_CustomMeleeAttack(random(5, 10) * 4)
		Goto See
		Missile:
			SAR3 GE 5 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
			SAR3 F 5 A_CustomMissile("Bloodshot_Grav", 27, 0, frandom(-4, 4))
			TNT1 A 0 A_FaceTarget
		Goto See
		Retaliate:
			SAR3 GE 6 A_FaceTarget
			TNT1 A 0  A_CustomMissile("Bloodshot_Grav", 27, 0)
			SAR3 F 7 A_CustomMissile("Bloodshot_Grav", 27, 0, -4)
			TNT1 A 0 A_FaceTarget
			TNT1 A 0  A_CustomMissile("Bloodshot_Grav", 27, 0)
			SAR3 F 7 A_CustomMissile("Bloodshot_Grav", 27, 0, 4)
			SAR3 EG 6
		Goto See
		Pain:
			SAR3 H 2
			SAR3 H 2 A_Pain
			TNT1 A 0 A_Jump(96, "Retaliate")
		Goto See
		Death:
			SAR3 I 8
			SAR3 J 8 A_Scream
			SAR3 K 4
			SAR3 L 4 A_NoBlocking
			SAR3 M 4
			SAR3 N -1
		Stop
		Death.Corpse:
			SAR3 N -1
		Stop
		Raise:
			SAR3 NMLKJI 5
		Goto See
	}
}

Actor Bloodshot
{
  Radius 3
  Height 6
  Speed 20
  Damage (2 * random(3, 6))
  Projectile
  RenderStyle Translucent
  Alpha 0.80
  +ThruGhost
  +DONTBLAST
  DeathSound "weapons/bloodx"
  States
  {
  Spawn:
    FBLD A 2 Bright A_CStaffMissileSlither
    FBLD A 0 A_SpawnItemEx("Bloodtrail",0,0,0,0,0,0,128)
    FBLD B 2 Bright A_CStaffMissileSlither
    FBLD B 0 A_SpawnItemEx("Bloodtrail",0,0,0,0,0,0,128)
    Loop
  Death:
    FBLD CDE 3 Bright
    Stop
  }
}

Actor Bloodtrail
{
  Radius 1
  Height 1
  Projectile
  +DONTBLAST
  RenderStyle Translucent
  Alpha 0.67
  +CLIENTSIDEONLY
  States
  {
  Spawn:
    TNT1 A 3
    FBLD FGH 3 BRIGHT
    Stop
  }
}

Actor Bloodshot_Grav : Bloodshot {
	Speed 22
	SeeSound "Weapons/bloodf"
	-NOGRAVITY
	States {
		Spawn:
			TNT1 A 0 NoDelay ThrustThingZ(0, 18, 0, 0)
		Goto Super::Spawn
	}
}