Actor UndeadMage : McM_Monster replaces Zombieman {
	Health 50
	Radius 20
	Height 56
	Speed 8
	Scale 0.925
	PainChance 184
	Monster
	+FLOORCLIP
    SeeSound "UndeadInitiate/See"
    ActiveSound "UndeadInitiate/Act"
    painsound "UndeadInitiate/Pain"
    deathsound "UndeadInitiate/Death"
	Obituary "%o succumbed to an Undead Mage's magic."
	Species "Imp"
	DropItem "Clip"
	Tag "Undead Mage"
	+NODAMAGETHRUST
	+DONTBLAST
	+NODROPOFF
	States {
		Idle:
			CMYS AB 10 A_Look
		Loop
		CanRaiseSee:
			CMYS AABBCCDD 3 A_VileChase
		Loop
		See:
			TNT1 A 0 A_JumpIfInventory("MCM_IgnoreToggle", 1, "SeeCont")
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "CanRaiseSee")
		SeeCont:
			CMYS AABBCCDD 3 A_FastChase
		Loop
		Missile:
			CMYS E 8 A_FaceTarget
			CMYS F 0 A_CustomMissile ("CultMysticShot",46,-5,0,1,0)
			CMYS F 0 A_CustomMissile ("CultMysticShot",46,5,0,1,0)
			CMYS F 8 Bright A_PlaySound("monster/culatk")
		Goto See
		Pain:
			CMYS G 3
			CMYS G 3 A_Pain
		Goto See
		Heal:
			CMYS E 0 A_PlaySound("monster/cultre")
			CMYS E 0 A_ChangeFlag("NoPain", 1)
			CMYS E 20 A_GiveInventory("MCM_IgnoreToggle", 1)
			CMYS E 0 A_ChangeFlag("NoPain", 0)
		Goto See
		Death:
			CMYS H 6
			CMYS I 6 A_PlayerScream
			CMYS JK 6
			CMYS L 6 A_NoBlocking
			CMYS M 6
			CMYS N -1
		Stop 
		XDeath:
			CMYS O 5 A_XScream
			CMYS P 5
			CMYS R 5 A_NoBlocking
			CMYS STUVW 5
			CMYS X -1
		Stop
		Raise:
			TNT1 A 0 A_ChangeFlag("NoPain",0)
			CMYS MLKJIH 5
		Goto See
		Death.Corpse:
			CMYS N -1
		Stop
	}
}

Actor CultMysticShotTrail {
	+CLIENTSIDEONLY
	+NOINTERACTION
	Renderstyle Add
	Alpha 0.825
	States {
		Spawn:
			TNT1 A 2
			TNT1 A 0 A_Jump(128, "Other")
			CMYP A 1 A_FadeOut(0.04125)
			TNT1 A 0 A_SetScale(scalex - 0.04125, scaley - 0.04125)
		Loop
		Other:
			CMYP A 1 A_FadeOut(0.04125)
			TNT1 A 0 A_SetScale(scalex - 0.04125, scaley - 0.04125)
		Loop
	}
}

ACTOR CultMysticShot {
	Speed 20
	Radius 4
	Height 4
	Damage (Random(4, 6))
	PROJECTILE
	+NoDamageThrust
	+ThruGhost
	+WindThrust
	+DONTBLAST
	Renderstyle Add
	States {
		Spawn:
			CMYP AB 2 Bright A_SpawnItem("CultMysticShotTrail")
		loop
		Death:
			CMYP CDEF 3 Bright
		stop
	}
}