ACTOR AngelOfDeath : McM_Monster replaces Arachnotron {
	Obituary "%o was raptured by an Angel of Death."
	Health 600
	Radius 48
	Height 64 
	Mass 1576
	Speed 8
	Painchance 96
	Scale 0.875
	SeeSound "angel/sight"
	Painsound "angel/pain"
	Deathsound "angel/death"
	Activesound "angel/active"
	MONSTER
	Tag "Angel of Death"
	+DONTBLAST
	+BOSSDEATH
	+FLOORCLIP
	+NOFEAR
	+DONTHURTSPECIES
	+DONTHARMSPECIES
	States {
		Idle:
			LMDA AB 10 A_Look
		loop
		See:
			LMDA AABBCCDD 3 A_Chase
		loop
		Missile:
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "PipeBomb")
		Chaingun:
			LMDA E 10 A_FaceTarget
			TNT1 A 0 A_PlaySound("angeltracer/fire", CHAN_WEAPON)
			LMDA F 3 bright A_CustomMissile ("BulletPierce", 56, 22, 0, 0)
			TNT1 A 0 A_PlaySound("angeltracer/fire", CHAN_WEAPON)
			LMDA G 3 bright A_CustomMissile ("BulletPierce", 56, -22, 0, 0)
			TNT1 A 0 A_PlaySound("angeltracer/fire", CHAN_WEAPON)
			LMDA F 3 bright A_CustomMissile ("BulletPierce", 56, 22, 0, 0)
			TNT1 A 0 A_PlaySound("angeltracer/fire", CHAN_WEAPON)
			LMDA G 3 bright A_CustomMissile ("BulletPierce", 56, -22, 0, 0)
			LMDA G 0 A_CPosRefire
		goto Chaingun+1
		PipeBomb:
			TNT1 A 0 A_Jump(128, "PipebombCont")
		Goto Chaingun
		PipebombCont:
			LMDA I 8 A_FaceTarget
			LMDA J 3 bright A_CustomMissile ("PipeBomb", 56, 0)
			LMDA H 10 
			LMDA I 4 A_FaceTarget
			LMDA J 3 bright A_CustomMissile ("PipeBomb", 56, 0)
			LMDA H 10
			LMDA H 0 A_Jump (127, "Another")
			Goto See
		Another:
			LMDA I 6 A_FaceTarget
			LMDA J 3 bright A_CustomMissile ("PipeBomb", 56, 0)
			LMDA H 8
		Goto See
		Pain:
			LMDA H 3
			LMDA H 3 A_Pain
			TNT1 A 0 A_Jump(128, "Missile")
		Goto See
		Death:
			LMDA H 4 A_Scream
			TNT1 A 0 A_NoBlocking
			LMDA KLMNOPQ 5
			TNT1 A 0 A_PlaySound("angel/collapse")
			LMDA RS 5
			LMDA TU 6
			LMDA V -1 A_BossDeath
		Stop
		Death.Corpse:
			LMDA V -1
		Stop
		Raise:
			LMDA UTSRQPONMLKJ 3
		Goto See
	}
}

ACTOR PipeBomb {
	Radius 8
	Height 16
	Speed 28
	Damage (4 * random(4, 5))
	DamageType "BigSpider"
	Scale 1.35
	Seesound "pipebomb/fire"
	Deathsound "pipebomb/explode"
	Projectile
	+THRUGHOST
	+DONTBLAST
	States {
		Spawn:
			LMPI A 3 bright
			LMPI B 3 bright A_PlaySound("pipe/whoosh")
			LMPI C 3 bright
			LMPI D 3 bright A_PlaySound("pipe/whoosh")
			LMPI E 3 bright
		loop
		Death:
			TNT1 A 0 A_Explode(24, 72, 0)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,  0)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0, 36)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0, 72)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0, 108)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,144)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,180)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,216)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,252)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,288)
			FBXP A 0 A_SpawnItemEx("BulletPierce",0,0,0,35,0,0,324)
			TNT1 A 0 A_SetScale(0.925, 0.925)
			MACX A 2 Bright
			MACX BCDEFGHIJ 2 Bright
		stop
	}
}

ACTOR BulletPierce {
	radius 3
	height 6
	speed 32
	damage (2 * random(1, 2))
	Scale 0.875
	seesound "angeltracer/explode"
	deathsound "angeltracer/explode"
	PROJECTILE
	+THRUGHOST
	+RIPPER
	+DONTBLAST
	Decal "BulletChip"
	BounceType "Hexen"
	BounceCount 2
	BounceFactor 1.0
	states {
		Spawn:
			LMPB A 1 bright
		Loop
		Death:
			TNT1 A 1 bright
		Stop
	}
}