Actor Abomination : McM_Monster replaces Fatso {
	Health 600
	Radius 48
	Height 64
	Speed 12
	Scale 1.1
	PainChance 48
	Mass 2048
	SeeSound "Abomination/See"
	PainSound "Abomination/Pain"
	DeathSound "Abomination/Death"
	ActiveSound "Abomination/Active"
	Monster
	+FloorClip
	+MissileMore
	+BOSSDEATH
	Species "Fatso"
	+DONTHURTSPECIES
	+NOINFIGHTING
	+DONTBLAST
	Obituary "%o was cremated by an Abomination."
	Tag "Abomination"
	States {
		Idle:
			FAT2 AAAAAAAAAABBBBBBBBBB 1 A_Look
		Loop
		See:
			FAT2 ABC 6 A_Chase
			FAT2 DEF 6 A_Chase
		Loop
		Missile:
			TNT1 A 0 A_PlaySoundEx("Abomination/Attack", "SoundSlot6", 0)
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "Missile2")
		MissileCont:
			FAT2 GGGG 3 A_FaceTarget
		MisFire:
			FAT2 V 4 Bright A_CustomMissile("AbominationAttack1", 24, 41, 0)
			FAT2 IGG 3 A_FaceTarget
			FAT2 K 0 A_SpidReFire
			FAT2 U 4 Bright A_CustomMissile("AbominationAttack1", 24, -41, 0)
			FAT2 GI 3 A_FaceTarget
			FAT2 K 0 A_Jump(96, "GiveUp")
			FAT2 K 0 A_SpidReFire
		Goto MisFire
		GiveUp:
			HECT K 0
		Goto See
		Missile2:
			TNT1 A 0 A_JumpIfCloser(384, "Missile2Cont")
		Goto MissileCont
		Missile2Cont:
			FAT2 GGGG 3 A_FaceTarget
			FAT2 H 0 A_CustomMissile("AbominationAttack1", 24, 41, Random(-4, 2))
			FAT2 H 4 Bright A_CustomMissile("AbominationAttack1", 24, -41, Random(-2, 4))
			FAT2 IGG 4 A_FaceTarget
			FAT2 H 0 A_CustomMissile("AbominationAttack1", 24, 41, Random(-4, 2))
			FAT2 H 4 Bright A_CustomMissile("AbominationAttack1", 24, -41, Random(-2, 4))
			FAT2 IGG 4 A_FaceTarget
			FAT2 H 0 A_CustomMissile("AbominationAttack1", 24, 41, Random(-4, 2))
			FAT2 H 4 Bright A_CustomMissile("AbominationAttack1", 24, -41, Random(-2, 4))
			FAT2 GI 4 A_FaceTarget
			FAT2 K 0 A_Jump(200, 2)
			FAT2 K 0 A_SpidReFire
		Goto Missile2
			FAT2 K 0
		Goto See
		Pain:
			FAT2 J 10 A_Pain
			TNT1 A 0 A_JumpIfInventory("MCM_BehaviorToggle", 1, "Missile")
			FAT2 J 4
		Goto See
		Death:
			FAT2 K 6 A_Scream
			FAT2 L 6
			FAT2 M 6
			FAT2 N 6
			FAT2 O 6
			FAT2 P 6 A_Fall
			FAT2 Q 6
			FAT2 R 6
			FAT2 S 6
			FAT2 T -1 A_BossDeath
		Stop
		Raise:
			FAT2 SRQPONMLK 6
		Goto See
		Death.Corpse:
			FAT2 T -1
		Stop
	}
}

ACTOR AbominationAttack1 {
	Radius 8
	Height 8
	Speed 28
	Damage (5 * random(5, 6))
	PROJECTILE
	+FORCEXYBILLBOARD
	+MTHRUSPECIES
	+FORCERADIUSDMG
	+DONTBLAST
	+FOILINVUL
	Seesound "weapons/macefi"
	DeathSound "weapons/maceex"
	States {
		Spawn:
			RIP1 AAABBBCCC 1 Bright A_SpawnItemEx("RedPuff",0,0,0,0,0,0,0,8)
		loop
		Death:
			RIP1 D 0 Bright A_SetTranslucent (0.75,1)
			RIP1 D 1 Bright A_Explode(18, 96)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,0,0,0)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,60,0,0)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,120,0,0)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,180,0,0)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,240,0,0)
			RIP1 D 0 Bright A_SpawnItemEx("AbominationAttack2",0,0,0,32,0,0,300,0,0)
			RIP1 DEFGH 3 Bright
		stop
	}
}

ACTOR AbominationAttack2Trail
{
   Radius 5
   Height 5
   +FORCEXYBILLBOARD
   +NOINTERACTION
   +CLIENTSIDEONLY
	RenderStyle Add
	Alpha 0.5
   States
   {
   Spawn:
      RIP2 AB 2 Bright A_Fadeout(0.07)
      loop
   }
}

ACTOR AbominationAttack2 {
   Radius 5
   Height 5
   Damage (2)
   PROJECTILE
   Speed 24
   +RIPPER
   +FORCEXYBILLBOARD
   +MTHRUSPECIES
   +DONTBLAST
   +FOILINVUL
   +NODAMAGETHRUST
   DeathSound "weapons/firex2"
   States {
		Spawn:
			RIP2 AAA 1 Bright A_SpawnItemEx("AbominationAttack2Trail")
			RIP2 BBB 1 Bright A_SpawnItemEx("AbominationAttack2Trail")
		loop
		Death:
			RIP2 C 0 Bright A_SetTranslucent (0.67,1)
			RIP2 CDEFG 3 Bright
		stop
   }
}