actor WanaanDetectorKNDM 11872
{
	//$Category MM8BDM-Interactive Props
	//$Title Wanaan (KNDM)
	//$Sprite WANND0

	PROJECTILE
	+DONTBLAST
	+FLOORHUGGER
	+DONTREFLECT
	+HITTARGET
	height 2
	Radius 28
	Damage (0)
	scale 2.0
	
	States
	{
		Spawn:
			TNT1 A 1
			wait
		Death:
			TNT1 A 15 // Adjust this delay for startup time
			TNT1 A 0 A_SpawnItemEX("WanaanKNDM",0,0,0,0,0,0,0,SXF_TRANSFERPOINTERS)
			TNT1 A 0 A_RearrangePointers(AAPTR_NULL, AAPTR_NULL, AAPTR_NULL)
			TNT1 A 9 // Adjust this delay for recrunch time
			TNT1 A 0 A_SpawnItemEx("WanaanDetectorKNDM")
			stop
	}	
}

actor WanaanKNDM : BasicWatcher
{
	Scale 2.0
	+FORCEYBILLBOARD
	renderstyle normal
	States
	{
		Spawn:
			WANN A 0
			WANN ABD 2
			WANN C 0 A_PlaySoundEx("misc/wanaan","Voice")
			WANN C 3 A_SpawnItemEx("WanaanDamagerKNDM", 0, 0, 32, 0, 0, 0, 0, SXF_TRANSFERPOINTERS)
			WANN CBA 2
			TNT1 A 1
			stop
	}
}

actor WanaanDamagerKNDM : BasicHazardExplosion
{
	damagetype "WanaanKNDM"
	Obituary "%o was crunched by %k's Wanaan."
	States
	{
		Spawn:
			TNT1 A 0 
			goto Explode
		Credit:
			TNT1 A 35 ACS_NamedExecuteWithResult("core_propexplode", 25, 32, 0)
			stop
		NoCredit:
			TNT1 A 35 A_Explode(25,32,0)
			stop
	}
}

actor HazardCredit_WanaanDamagerKNDM : BasicACSDamager
{
	damagetype "WanaanKNDM"
	obituary "%o was crunched by %k's Wanaan."
}

actor HazardTag_WanaanKNDM : BasicACSDamager
{
	damagetype "WanaanKNDM"
	obituary "%o was crunched by a Wanaan while fighting %k."
}

actor KNDM_Lamp1 11870
{
	-SOLID
	+NOGRAVITY
	+ALLOWCLIENTSPAWN
	height 17
	+FORCEYBILLBOARD
	radius 32
	scale 2.5
	States
	{
		Spawn:
			KNLP A -1
			stop
	}
}

actor KNDM_Lamp2 11871
{
	-SOLID
	+NOGRAVITY
	+RANDOMIZE
	+ALLOWCLIENTSPAWN
	height 13
	+FORCEYBILLBOARD
	radius 32
	scale 2.5
	States
	{
		Spawn:
			KNLP A 60
			KNLP B 20
			KNLP A 2
			KNLP B 2
			KNLP A 2
			KNLP B 2
			KNLP A 60
			KNLP B 2
			KNLP A 20
			KNLP B 2
			KNLP A 2
			KNLP B 2
			loop
	}
}
