actor OriginalDuo : ClassBase
{
Player.ScoreIcon "C_08J0X"
player.displayname "OriginalDuo"
player.soundclass "originalduoc"

player.maxhealth 1350
health 1350
player.jumpz 10
player.forwardmove 0.76, 0.76
player.sidemove 0.74, 0.74

player.startitem "OriginalDuoBoss"
player.startitem "OriginalDuoMeteorBoss"
player.startitem "DuoJusticeAmmo", 42

player.weaponslot 1, "OriginalDuoBoss"
player.weaponslot 2, "OriginalDuoMeteorBoss"

States
{
Spawn:
ODUO A 0
ODUO B 1
ODUO A 1
wait
See:
ODUO BCDE 5
Goto Spawn
Missile:
ODUO FF 1 A_JumpIfInventory("ODuoMeteorFlag",1,"MissileRise")
ODUO F 0 A_JumpIfInventory("ODuoRamFlag",1,"Missile2")
ODUO F 3
ODUO G 4
goto Spawn
Missile2:
ODUO G 2
goto Missile
MissileRise:
ODUO MMNNOO 1 A_JumpIfInventory("ODuoMeteorGo",1,"MissileMeteor")
loop
MissileMeteor:
ODUO PPQQ 1 A_JumpIfInventory("ODuoMeteorStop",1,"Spawn")
loop

Missile2_Pain:
ODUO H 0 A_SpawnItemEx("DelayPainFX")
goto Missile2
MissileRise_Pain:
ODUO H 0 A_SpawnItemEx("DelayPainFX")
goto MissileRise+1

ClassPain:
ODUO H 0 A_JumpIfInventory("ODuoMeteorFlag",1,"MissileRise_Pain")
ODUO H 0 A_JumpIfInventory("ODuoRamFlag",1,"Missile2_Pain")
goto PainContinue
ClassDeath:
ODUO H 0
goto DeathContinue
}
}