actor ScorchWheelBoss : BaseMM8BDMWep_CBM
{
tag "$TAGC_7H"
dropitem "ScorchWheelWepCDropped"
Weapon.AmmoUse 28
Weapon.AmmoGive 0
Obituary "$OB_SCORCHWHEEL"
weapon.ammotype "DieselJuiceAmmo"
weapon.ammotype2 "CrashDriveAmmo"
States
{
Spawn:
C_07 H 1
loop
Ready:
TUCA A 0 ACS_ExecuteAlways(998,0,DYE_TURBOMAN)
goto Ready0
Ready0:
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready1")
goto Ready1a
Ready1:
TUCA A 0 A_JumpIfInventory("DieselJuiceAmmo",28,"Ready2")
TUCA A 4 A_WeaponReady(12)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready1")
Goto Ready1a
Ready1a:
TUCA A 0 A_JumpIfInventory("DieselJuiceAmmo",28,"ReadyX")
TUCA A 4 A_WeaponReady(4)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
loop
Ready2:
TUCA A 4 A_WeaponReady(8)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready2")
goto ReadyX
ReadyX:
TUCA A 4 A_WeaponReady
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
loop

Deselect:
TUCA AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
TUCA A 1 A_Lower
Loop
Select:
TUCA AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
TUCA A 1 A_Raise
Loop

Fire:
TUCA A 0 A_JumpIfInventory("TurboCarFlag",1,"AltfireHonk")
TUCA BCDEF 2
TUCA A 0 A_PlaySoundEx("weapon/WheelGoGoGo","Weapon")
TNT1 A 0 A_GiveInventory("ShieldCheck",1)
TNT1 A 0 A_SpawnItemEx("TurbomanWheelWarper",0,0,0,0,0,0,0,1)
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,140,100)//145
TUCA A 0 A_JumpIfInventory("IsBot",1,"BotFireH")
Goto FireH
FireH2:
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
TNT1 A 0
goto FireH3
FireH:
TNT1 A 0 A_JumpIfInventory("TurboWheelCount",45,"FireH2")
TNT1 A 0 A_GiveInventory("TurboWheelCount",1)
TNT1 A 1
TNT1 A 0 A_Refire(1)
Goto FireT
TNT1 A 1 A_JumpIfInventory("PowerRage_ST",1,"FireH")
TNT1 A 0 A_Refire("FireH")
Goto FireT
FireH3:
TNT1 A 1 A_RailWait
TNT1 A 0 A_Refire("FireH3")
Goto FireT

FireT:
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
TNT1 A 0 A_GiveInventory("TurbomanMainCheck_P",1)
TNT1 A 0 A_TakeInventory("WheelFrameCheck",99)
TNT1 A 0 A_TakeInventory("ShieldCheck",99)
TNT1 A 0 A_TakeInventory("TurboWheelCount",99)
TUCA A 2 Offset(0,54)A_ClearRefire
TUCA A 2 Offset(0,41)A_ClearRefire
TUCA A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
Goto Ready0

Altfire:
TUCA A 0 A_JumpIfInventory("TurboCarFlag",1,"AltfireStop")
TUCA A 0 A_JumpIf(z-floorz==0,"Altfire2")
//TUCA A 0 SetPlayerProperty(0,0,0)
Goto Ready0
Altfire2:
TUCA G 0 A_Stop
TUCA G 0 SetPlayerProperty(0,1,0)
TUCA G 0 A_TakeInventory("TurboNoCarFlag",9)
TUCA G 0 A_GiveInventory("TurboCarFlag",1)
TUCA G 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,0,1)
TUCA G 0 A_Refire("Altfire3")
goto Altfire3
Altfire3:
TUCA G 0 A_GiveInventory("CrashDriveAmmo",1)
TUCA G 0 A_SpawnItemEx("TurboCarDust_H",0,0,0,0,0,0,0,1)
TUCA G 2 Offset(0,32)A_PlaySoundEx("classes/CarCharge","Weapon")
TUCA G 0 A_Refire(1)
goto AltfireGo
TUCA G 0 A_GiveInventory("DieselJuiceAmmo",1)
TUCA G 0 A_GiveInventory("CrashDriveAmmo",1)
TUCA G 0 A_SpawnItemEx("TurboCarDust_H",0,0,0,0,0,0,0,1)
TUCA G 2 Offset(0,27)A_PlaySoundEx("classes/CarCharge","Weapon")
TUCA G 0 A_Refire("Altfire3")
goto AltfireGo

AltfireGo:
//TUCA G 0 A_GiveInventory("SelfTotallyUnfrozen",1)
TUCA G 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,7,1)
TUCA G 0 A_GiveInventory("TurboGoDelay",1)
TUCA G 0 A_PlaySoundEx("classes/CarGoGo","Body")
TUCA G 0 A_ChangeVelocity(23,0,momz,3)
TUCA G 0 A_JumpIfInventory("CrashDriveAmmo",14,"AltfireDrive")
TUCA G 0 A_GiveInventory("TurboHonkDelayX",1)
goto AltfireDrive
AltfireHonk:
TUCA G 0 A_GiveInventory("TurboHonkDelay",34)
TUCA G 0 A_GiveInventory("TurbomanAltX_CI",1)
TUCA G 0 A_PlaySound("classes/CarHonk",7,0.5)//SoundSlot7
goto AltfireDrive1
AltfireDrive:
TUCA G 0 A_GiveInventory("TurbomanBoost_P",1)
TUCA G 0 A_TakeInventory("CrashDriveAmmo",1)
TUCA G 0 A_GiveInventory("TurboCarRadius_P",1)
TUCA G 0 A_JumpIfInventory("TurboHonkDelayX",1,"AltfireDrive1")
TUCA G 0 A_JumpIfInventory("TurboHonkDelay",1,"AltfireDrive1")
TUCA G 0 A_JumpIfInventory("TurboGoDelay",1,"AltfireDrive2")
TUCA G 1 Offset(0,32)A_WeaponReady(3)
TUCA G 0 A_GiveInventory("TurboCarRadius_P",1)
TUCA G 1 Offset(0,27)A_WeaponReady(3)
TUCA G 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive1://Main
TUCA G 0 A_JumpIfInventory("TurboGoDelay",1,"AltfireDrive3")
TUCA G 1 Offset(0,32)A_WeaponReady(7)
TUCA G 0 A_GiveInventory("TurboCarRadius_P",1)
TUCA G 1 Offset(0,27)A_WeaponReady(7)
TUCA G 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive2://Alt
TUCA G 1 Offset(0,32)A_WeaponReady(11)
TUCA G 0 A_GiveInventory("TurboCarRadius_P",1)
TUCA G 1 Offset(0,27)A_WeaponReady(11)
TUCA G 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive3://Both
TUCA G 1 Offset(0,32)A_WeaponReady(15)
TUCA G 0 A_GiveInventory("TurboCarRadius_P",1)
TUCA G 1 Offset(0,27)A_WeaponReady(15)
TUCA G 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireStop:
TNT1 A 0 A_GiveInventory("TurboCarEnd_P",1)
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,10,1)
TNT1 A 0 SetPlayerProperty(0,0,0)
TNT1 A 4
TUCA A 2 Offset(0,76)
TUCA A 2 Offset(0,59)//A_TakeInventory("TurboHonkDelay",999)
TUCA A 2 Offset(0,46)//A_TakeInventory("TurboHonkDelay",999)
TUCA A 2 Offset(0,37)A_GiveInventory("TurboNoCarFlag",1)
TUCA A 0 A_GiveInventory("TurboAltDelay",1)
Goto Ready0

BotFireH:
TNT1 A 0 A_JumpIfInventory("TurboWheelCount",45,"FireT")
TNT1 A 0 A_GiveInventory("TurboWheelCount",2)
TNT1 A 1 A_Jump(10,"FireT")
TNT1 A 0 A_Refire(1)
Goto FireT
TNT1 A 1 A_GiveInventory("DieselJuiceAmmo",random(1,2))
TNT1 A 0 A_Refire("BotFireH")
Goto FireT

NoAmmo:
TUCA A 0
Goto Ready0
}
}

actor DieselJuiceAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 84
+INVENTORY.IGNORESKILL
}

actor CrashDriveAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 56
+INVENTORY.IGNORESKILL
}


actor TurboWheelCount : Inventory
{
inventory.amount 1
inventory.maxamount 45
}

actor TurboCarFlag : Inventory
{
inventory.amount 1
inventory.maxamount 6
}

actor TurboNoCarFlag : OnceC {}

actor TurboCarCount : Inventory
{
inventory.amount 1
inventory.maxamount 56
}

actor TurboHonkDelay : Inventory
{
inventory.amount 1
inventory.maxamount 34
}
actor TurboHonkDelayX : Powerup
{
Powerup.Duration 9
}

actor TurboGoDelay : Powerup
{
Powerup.Duration 10
}
actor TurboAltDelay : Powerup
{
Powerup.Duration 55
}

actor TurboCarRadiusDelay : Powerup
{
+INVENTORY.ADDITIVETIME
Powerup.Duration 2
}


actor TurbomanMainCheck_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("TurboWheelCount",45,"Pickup2")
TNT1 A 0 A_GiveInventory("TurbomanMain_CI",1)
stop
Pickup2:
TNT1 A 0 A_GiveInventory("TurbomanMain1_CI",1)
stop
}
}

actor TurbomanBoost_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz==0,"Ground")
TNT1 A 0 A_Recoil(-3.15)
stop
Ground:
TNT1 A 0 A_Recoil(-7.5)
stop
}
}

actor TurboCarRadius_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("TurboCarRadiusDelay",1,"No")
TNT1 A 0 A_JumpIfInventory("TurboHonkDelay",1,"Pickup2")
TNT1 A 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"Pickup_S")
goto End
Pickup_S:
TNT1 AA 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
goto End

Pickup2:
TNT1 A 0 A_SpawnItemEx("TurboCarRadiusW",0,0,28,momx,momy,momz,0,8)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"Pickup2_S")
goto End
Pickup2_S:
TNT1 AA 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
goto End
End:
TNT1 A 0 A_JumpIfInventory("PowerRage_ST",1,"EndR")
TNT1 A 0 A_GiveInventory("TurboCarRadiusDelay",1)
goto EndR
EndR:
TNT1 A 0 A_GiveInventory("TurboCarRadiusDelay",1)
goto End2
End2:
TNT1 A 0 A_JumpIf(z-floorz==0,"EndX")
goto No
EndX:
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_BitX",-8,-16,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_BitX",-8,16,0,0,0,0,0,1)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"EndX_S")
goto No
EndX_S:
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_BitX",0,0,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_BitX",-16,-32,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_BitX",-16,32,0,0,0,0,0,1)
goto No

No:
TNT1 A 0 A_TakeInventory("TurboHonkDelay",1)
stop
}
}

actor TurboCarEnd_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_TakeInventory("CrashDriveAmmo",999)
TNT1 A 0 A_TakeInventory("TurboHonkDelay",999)
TNT1 A 0 A_TakeInventory("TurboCarFlag",999)
TNT1 A 0 A_TakeInventory("TurboCarCount",999)
TNT1 A 0 A_GiveInventory("TurboNoCarFlag",1)
stop
}
}

actor TurbomanWheelWarper : ShieldWarper_CBM
{
+NOTIMEFREEZE
States
{
Shield:
Y_7H A 0 A_JumpIfInventory("Once",1,2)
Y_7H A 0 A_JumpIfInTargetInventory("TurboWheelCount",45,"ShieldScale")

Y_7H A 0 A_JumpIfInTargetInventory("PowerRage_ST",1,"ShieldR1")
Y_7H AAABBBCCC 1 A_Warp(2,0,0,0,0,24)

Y_7H D 0 A_JumpIfInventory("Once",1,2)
Y_7H D 0 A_JumpIfInTargetInventory("TurboWheelCount",45,"ShieldScale2")

Y_7H D 0 A_JumpIfInTargetInventory("PowerRage_ST",1,"ShieldR2")
Y_7H DDDEEEFFF 1 A_Warp(2,0,0,0,0,24)
loop
ShieldR1:
Y_7H AABBCC 1 A_Warp(2,0,0,0,0,24)
goto Shield+12
ShieldR2:
Y_7H DDEEFF 1 A_Warp(2,0,0,0,0,24)
goto Shield
ShieldScale:
Y_7H A 0 A_GiveInventory("Once",1)
Y_7H A 0 A_SetScale(3.0,3.0)
goto Shield+2
ShieldScale2:
Y_7H A 0 A_GiveInventory("Once",1)
Y_7H A 0 A_SetScale(3.0,3.0)
goto Shield+14
}
}

actor TurboScorchW
{
Translation "202:202=210:210","199:199=42:42"
damagetype "TurboM_Wheel"
Obituary "$OB_SCORCHWHEEL"
-SOLID
+MISSILE
+RIPPER
+BRIGHT
-NOGRAVITY
maxstepheight 24
Damage 0
Radius 18
Height 40
speed 16
scale 2.5
States
{
Spawn:
Y_7H A 0
Y_7H ABCDEF 2 A_SpawnItemEx("TurboScorchW_Explo",0,0,18)
loop
Death:
TNT1 A 0 A_SpawnItemEx("TurboScorchW3",0,0,0,16,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("CBM_OilPitIgnite",0,0,8)
stop
}
}

actor TurboScorchWB : TurboScorchW{translation "202:202=205:205","199:199=74:74"}
actor TurboScorchWR : TurboScorchW{translation "202:202=171:171","199:199=41:41"}
actor TurboScorchWO : TurboScorchW{translation "202:202=104:104","199:199=128:128"}
actor TurboScorchWP : TurboScorchW{translation "202:202=229:229","199:199=232:232"}

actor TurboScorchW_Explo : BasicExplosion
{
damagetype "TurboM_Wheel"
Obituary "$OB_SCORCHWHEEL"
+EXPLODEONDEATH
Mass 80
States
{
Spawn:
TNT1 A 0
TNT1 A 2 A_Explode(Mass,56,0,0,18)
stop
}
}
actor TurboScorchW_Explo2 : TurboScorchW_Explo
{
Mass 90
}
actor TurboScorchW_Explo3 : TurboScorchW_Explo
{
Mass 100
}

actor TurboScorchW1 : TurboScorchW
{
Speed 22
States
{
Death:
TNT1 A 0 A_SpawnItemEx("TurboScorchW2",0,0,0,22,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("CBM_OilPitIgnite",0,0,8)
stop
}
}

actor TurboScorchW1B : TurboScorchW1{translation "202:202=205:205","199:199=74:74"}
actor TurboScorchW1R : TurboScorchW1{translation "202:202=171:171","199:199=41:41"}
actor TurboScorchW1O : TurboScorchW1{translation "202:202=104:104","199:199=128:128"}
actor TurboScorchW1P : TurboScorchW1{translation "202:202=229:229","199:199=232:232"}

actor TurboScorchW2 : TurboScorchW
{
damagetype "TurboM_Wheel"
Obituary "$OB_SCORCHWHEEL"
+EXPLODEONWATER
+DONTSPLASH
+NOEXPLODEFLOOR
+STEPMISSILE
States
{
Spawn:
Y_7H A 0
Y_7H ABCDEF 2 A_GiveInventory("TurboScorchW2_P",1)
Y_7H A 0 A_SpawnItemEx("CBM_OilPitIgnite",0,0,0)
loop

Death:
TNT1 AAAA 0 A_SpawnItemEx("TurboM_ScorchBitFX",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
TNT1 A 1 A_SpawnItemEx("CBM_OilPitIgnite",0,0,8)
stop
}
}

actor TurboScorchW3 : TurboScorchW2
{
States
{
Spawn:
Y_7H A 0
Y_7H ABCDEF 2 A_SpawnItemEx("TurboScorchW_Explo3",0,0,18)//A_Explode(110,96,0)
Y_7H A 0 A_SpawnItemEx("CBM_OilPitIgnite",0,0,0)
loop
}
}


actor TurboScorchW2_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_SpawnItemEx("TurboScorchW_Explo2",0,0,18)
TNT1 A 0 A_JumpIf(z-floorz==0,"Pickup2")
stop
Pickup2:
TNT1 A 0 A_SpawnItemEx("TurboScorchW2_Bit",0,0,0,0,0,0,0,1)
stop
}
}

actor TurboScorchW2_Bit
{
PROJECTILE
damagetype "TurboM_WheelBit"
Obituary "$OB_TURBOSKID"
+DONTBLAST
+FLOORHUGGER
+BRIGHT
reactiontime 10
Damage (50)
Height 16
Radius 18
Speed 0
Scale 2.0
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("CBM_OilPitIgnite",0,0,8)
TUCA RSTU 3
TUCA R 0 A_CountDown
goto Spawn+2
}
}

actor TurboScorchW2_BitX : TurboScorchW2_Bit
{
-FLOORHUGGER
reactiontime 6
Height 12
Radius 12
Scale 1.5
}

actor TurboM_ScorchBitFX
{
+RIPPER
-NOGRAVITY
+CLIENTSIDEONLY
-SOLID
//+NOINTERACTION
+BRIGHT
damage 0
Height 2
Radius 2
scale 2.5
States
{
Spawn:
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
Y_7H O 1
TNT1 A 1
stop
}
}


actor TurboCarDust_H : BasicHelper
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("TurboCarDustFX",-2, 24,0,-2,0,0,0,129)
TNT1 A 0 A_SpawnItemEx("TurboCarDustFX",-2,-24,0,-2,0,0,0,129)
TNT1 A 1
stop
}
}

actor TurboCarDustFX : BasicClientSide
{
Scale 1.0
States
{
Spawn:
HSHH P 0
HSHH PQR 5
stop
}
}

actor TurboCarRadius : BasicExplosion
{
Obituary "$OB_TURBORAM"
Damagetype "TurboM_Ram"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(40,128,0,0,24)//80 160
stop
}
}

actor TurboCarRadiusW : TurboCarRadius
{
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(20,128,0,0,24)
stop
}
}

actor TurboHonkBlast : BasicExplosion
{
Translation "192:192=4:4", "198:198=73:73"
damagetype "TurboM_Honk"
Obituary "$OB_TURBOHONK"
+BRIGHT
scale 2.5
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("TurboHonkBlastFX1",0,0,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("TurboHonkBlastFX2",0,0,0,0,0,0,0,1)
TNT1 A 0 A_Explode(120,256,0,0,256)
X_1G EFGHI 1
TNT1 A 0 A_Explode(120,256,0,0,256)
X_1G JKLMN 1
stop
}
}


actor TurboHonkBlastB : TurboHonkBlast{translation "192:192=205:205", "198:198=74:74"}
actor TurboHonkBlastR : TurboHonkBlast{translation "192:192=171:171", "198:198=41:41"}
actor TurboHonkBlastO : TurboHonkBlast{translation "192:192=104:104", "198:198=128:128"}
actor TurboHonkBlastP : TurboHonkBlast{translation "192:192=229:229", "198:198=232:232"}

actor TurboM_HonkProtect : PowerProtection
{
Powerup.Duration 8
DamageFactor "TurboM_Honk", 0.0
}

actor TurboHonkBlastFX1 : BasicClientSide
{
+BRIGHT
Scale 2.0
States
{
Spawn:
TNT1 A 1
X_1G EFGHIJKLMN 1
stop
}
}

actor TurboHonkBlastFX2 : BasicClientSide
{
+BRIGHT
Scale 1.5
States
{
Spawn:
TNT1 A 1
X_1G EFGHIJKLMN 1
stop
}
}


actor TurbomanMain_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TurboScorchW",0,1,0,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TurboScorchWB",0,1,0,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TurboScorchWR",0,1,0,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TurboScorchWO",0,1,0,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TurboScorchWP",0,1,0,0)
goto Done
}
}

actor TurbomanMain1_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TurboScorchW1",0,1,0,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TurboScorchW1B",0,1,0,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TurboScorchW1R",0,1,0,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TurboScorchW1O",0,1,0,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TurboScorchW1P",0,1,0,0)
goto Done
}
}

actor TurbomanAltX_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlast",0,0,0,8)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastB",0,0,0,8)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastR",0,0,0,8)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastO",0,0,0,8)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastP",0,0,0,8)
goto Done
}
}