//Again, just cosmetic changes to the standard health and armor power ups

//===HEALTH STUFF===

//--HEALTH BONUS--

actor CAHealthFlask : healthbonus replaces healthbonus
{
	Inventory.PickupMessage "Drank from a life flask, gonna need more of this!"
	inventory.pickupsound "misc/lifeflask"
	scale 0.80
	states
	{
	spawn:
		LFCN ABCD 8 Bright
		loop
	}
}

//--STIM PACK--
	
actor CAStimpack : stimpack replaces stimpack
{
	Inventory.PickupMessage "Applied a stimpack, feelin better."
	inventory.pickupsound "misc/stimpack"
	scale 1
	states
	{
	spawn:
		STPK A 15 bright
		STPK ABCDEFGHH 4 Bright
		STPK H 15 bright
		STPK HGFEDCBAA 4 Bright
		loop
	}
}

//--MEDIKIT--

actor CAMedikit : medikit replaces medikit
{
	Inventory.PickupMessage "Used a Medikit, that's the stuff."
	Health.LowMessage 25, "Used a well needed medikit, now stop bleeding so much!"
	inventory.pickupsound "misc/medikit"
	scale 1
	states
	{
	spawn:
		LFMK AB 6 bright
		loop
	}
}

//--SOUL SPHERE--

actor CAMegashot : soulsphere replaces soulsphere
{
	Inventory.PickupMessage "Used a MEGA SHOT, that stings a little."
	Health.LowMessage 25, "Used a desperately needed MEGA SHOT, back into the fray!"
	inventory.pickupsound "misc/megashot"
	inventory.pickupflash "droppedstand"
	scale 1
	states
	{
	spawn:
		MGSH A 10 bright
		MGSH A 10 
		loop
	}
}

actor droppedstand
{
	+notimefreeze
	+cannotpush
	+movewithsector
	+dontsplash
	+noblockmap
	+thruactors
	-nogravity
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	scale 1
    States
    {
    Spawn:
		MGSH B 1200
		goto fadeout
	fadeout:
		MGSH B 20
		MGSH B 1 a_fadeout (0.10) 
		loop
	}
}


//===========================================================================
//===========================================================================
//===========================================================================

//===ARMOR STUFF===

//--ARMOR BONUS--

actor CAArmorGlobe : armorbonus replaces armorbonus
{
	Inventory.PickupMessage "Armor charge."
	inventory.pickupsound "misc/armorbonus"
	scale 1
	states
	{
	spawn:
		CAAG A 10 bright
		CAAG ABCDEE 4 Bright
		CAAG E 10 bright
		CAAG EDCBA 4 bright
		loop
	}
}

//--GREEN ARMOR--

actor CAGreenArmor : greenarmor replaces greenarmor
{
	Inventory.PickupMessage "Standard armor."
	inventory.pickupsound "misc/greenarmor"
	scale 1
	states
	{
	spawn:
		CAGA A 8 bright
		CAGA B 20 bright
		CAGA A 8 bright 
		loop
	}
}

//--BLUE ARMOR--

actor CABlueArmor : bluearmor replaces bluearmor
{
	Inventory.PickupMessage "Reinforced security armor!"
	inventory.pickupsound "misc/bluearmor"
	scale 1
	states
	{
	spawn:
		CABA A 8 bright
		CABA B 20 bright
		CABA A 8 bright 
		loop
	}
}


//--RED ARMOR--

actor CARedArmor : Megasphere replaces Megasphere
{
	Inventory.PickupMessage "Supercharged armor! Max HP and armor!"
	inventory.pickupsound "misc/redarmor"
	scale 1
	+floatbob
	states
	{
	spawn:
		MGAR A 15 bright
		MGAR A 15
		loop
	}
}


//===========================================================================
//===========================================================================
//===========================================================================

//POWER UPS

//--RADSUIT--

//--RADSUIT--

actor Radboots : custominventory replaces radsuit
{
	Inventory.PickupMessage "Rad anti-rad boots!"
	//inventory.pickupsound "subitems/upgradeitem"
	Inventory.Amount 1
	Inventory.MaxAmount 1
	inventory.pickupsound "misc/boots"
	Inventory.InterHubAmount 1
	+floatbob
	States
	{
	Spawn:
		RDBT A 10 bright
		RDBT A 4 
		Loop
	pickup:
		TNT1 A 0 a_giveinventory ("Bootprotection", 1)
		stop
	} 
}

actor bootprotection : powerironfeet
{
	Powerup.Duration -80
	Powerup.Color 0, 0, 0, 0
	inventory.maxamount 1
	//inventory.icon "RDBTB0"
	+INVENTORY.AUTOACTIVATE
}	


actor BootMeterHUD : PowerupGiver
{
	inventory.pickupmessage ""
	inventory.maxamount 0
	Powerup.Duration -80
	Powerup.Color 0, 0, 0, 0
	powerup.type "bootprotection"
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	Inventory.PickupSound ""
	states
	{
	Spawn:
		TNT1 A 0
		Stop
	}
}




//--INFRARED--

ACTOR Lightscope : PowerupGiver replaces infrared
{
	+COUNTITEM
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	inventory.pickupsound "rebounder/armed"
	Inventory.MaxAmount 0
	Powerup.Type "LightAmp"
	Inventory.PickupMessage "Light Amplification scope!"
	States
	{
	Spawn:
		LASC A 10 bright
		LASC A 10 
		Loop
	}
}

//--IDDQD ARMOR--

actor holoarmor : powerupgiver
{
	Inventory.PickupMessage "Impact Damage Detecting Quarantine Device!"
	inventory.pickupsound "misc/Invulnarmor"
    Powerup.Type "shieldprotection"
    Powerup.Duration -30
    inventory.maxamount 0
	Powerup.Color blue2 0.10
	renderstyle add
	alpha 0.90
    +notimefreeze
    +floatbob
    +bright
	+INVENTORY.BIGPOWERUP
	+INVENTORY.AUTOACTIVATE
    states
    {
    spawn:
		IQAM ABC 5
		loop
    }
}

actor powershieldprotection : powerprotection
{
    DamageFactor "Normal", 0.0
    +noradiusdmg
    +nopain
}


actor IDDQDbase : custominventory
{
	Inventory.PickupMessage ""
	scale 1
	+notimefreeze
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.QUIET
	+bright
	inventory.pickupflash "emptybase"
	states
	{
	spawn:
		TNT1 A 0
		IQBS A 1 a_spawnitemex ("holoarmor")
		goto waiting
	waiting:
		IQBS A 1
		loop
	}
}

actor Emptybase
{
	+notimefreeze
	+cannotpush
	+movewithsector
	+dontsplash
	+noblockmap
	+thruactors
	-nogravity
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	scale 1
    States
    {
    Spawn:
		IQBS B 1200
		goto fadeout
	fadeout:
		IQBS B 20
		IQBS B 1 a_fadeout (0.10) 
		loop
	}
}
	

actor BaseSpawner : randomspawner replaces InvulnerabilitySphere
{
	dropitem "IDDQDbase", 255,1
}


//--STEALTH ARMOR--

actor Invisoarmor : custominventory replaces blursphere
{
	Inventory.PickupMessage "Stealth Armor!"
	inventory.pickupsound "misc/stealtharmor"
    inventory.maxamount 0
    +notimefreeze
    +floatbob
    +bright
	+INVENTORY.BIGPOWERUP
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	states
	{
	spawn:
		VARM A 1
		loop
	pickup:
		TNT1 A 0
		TNT1 A 0 a_giveinventory ("Powershade",1)
		TNT1 A 0 a_giveinventory ("PowerStealthprotection",1)
		stop
	}
}


ACTOR PowerShade : PowerInvisibility
{
	Powerup.Duration -60
	Powerup.Strength 60
	Powerup.Mode "translucent"
}


actor powerstealthprotection : powerprotection
{
	Powerup.Duration -60
	DamageFactor "Normal", 0.6
}


//----------------------ALLMAP---------------------------

actor HoloMap : MapRevealer replaces allmap
{
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	+bright
	Inventory.MaxAmount 0
	inventory.pickupsound "misc/holomap"
	Inventory.PickupMessage "Downloaded a map of the level!"
	States
	{
	Spawn:
		HMP1 ABCDEF 2
		Loop
	}
}

