/*

==PLAKANOMICON==
An incredibly unorthodox magic tome, the Plakanomicon
lets the wielder manipulate brick magic. The two main
combat spells are a massive brick wall that slides along
the ground and runs foes down before exploding and sending
shrapnel all over the place.

As an alternate attack, the tome can be used to open a portal
from the planes of infinite bricking to rapidly hurl bricks 
in the direction where it was opened
*/

actor bricktoken : custominventory
{
	+notimefreeze
	+floatbob
	Inventory.PickupSound "brickbook/pickup"
	Inventory.PickupMessage "You got the Plakanomicon! Wield ancient brick magic!"
	states
	{
	spawn:
		BNPU A 8 bright
		BNPU A 5
		loop
	pickup:
		TNT1 A 0
		TNT1 A 0 a_jumpifinventory ("RevenantBox", 1, "dropboner")
		TNT1 A 0 a_jumpifinventory ("IcarusLauncher", 1, "dropIcarus")
		TNT1 A 0 a_jumpifinventory ("SKpistol", 1, "droppistol")
		TNT1 A 0 a_jumpifinventory ("ParticleSmasher", 1, "dropsmasher")
		TNT1 A 0 a_giveinventory ("tsbrick", 1)
		stop
	dropsmasher:
		TNT1 A 0
		TNT1 A 0 a_spawnitemex ("DroppedSmasher",1,0,15,random (-3,-6),0,random(2,4),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_takeinventory ("Particlesmasher", 1)
		TNT1 A 0 a_giveinventory ("TSbrick", 1)
		stop
	DropPistol:
		TNT1 A 0 
		TNT1 A 0 a_spawnitemex ("DroppedPistol",1,0,15,random (-3,-6),0,random(2,4),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_takeinventory ("SKPistol", 1)
		TNT1 A 0 a_giveinventory ("TSbrick", 1)
		stop
	DropIcarus:
		TNT1 A 0 
		TNT1 A 0 a_spawnitemex ("DroppedIcarus",1,0,15,random (-3,-6),0,random(2,4),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_takeinventory ("IcarusLauncher", 1)
		TNT1 A 0 a_giveinventory ("tsbrick", 1)
		stop
	DropBoner:
		TNT1 A 0 
		TNT1 A 0 a_spawnitemex ("DroppedBoner",1,0,15,random (-3,-6),0,random(2,4),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_takeinventory ("RevenantBox", 1)
		TNT1 A 0 a_giveinventory ("tsbrick", 1)
		stop
	}
}

actor droppedbrick
{
	+dropped
	+notimefreeze
	renderstyle ADD
	alpha 0.50
	states
	{
	spawn:
		BNPU A 60
		goto death
	death:
		TNT1 A 0
		TNT1 A 0 a_spawnitemex ("bricktoken")
		stop
	}
}




actor TSBrick : weapon
{
	+NOALERT
	+floatbob
	+AMMO_OPTIONAL
	+cheatnotweapon
	+NOAUTOAIM
	+INVENTORY.UNTOSSABLE
	Weapon.AmmoType "CrateEnergy"
	Weapon.SelectionOrder 20
	Weapon.Kickback 100
	weapon.bobstyle smooth
	weapon.bobrangex 0.1
	weapon.bobrangey 0.6
	weapon.bobspeed 2
	Tag "Plakanomicon"
	states
	{
	spawn:
		BNPU A 15
		BNPU A 4 bright
		loop
	select:
		TNT1 A 0
		TNT1 A 0 a_stopsound (CHAN_WEAPON)
		TNT1 A 0 a_stopsound (6)
		TNT1 A 0 a_playsound ("brickbook/draw",0)
		TNT1 A 0 a_jumpifinventory ("IAmTechMonk",1,"VisorSwap")
		Goto Draw
	VisorSwap:
		TNT1 A 0
		TNT1 A 0 a_takeinventory ("ArtiPainTimer",9999)
		TNT1 A 0 a_giveinventory ("CrateWeaponArmed",1)
		TNT1 A 0 a_giveinventory ("ArtiPainTimer",40)
	draw:
		TNT1 A 0
		TNT1 AAAAAAAAA 0 a_raise
		TNT1 A 1 a_raise
		loop
	Ready:
		BRK7 AB 2 a_jumpifinventory ("CrateEnergy",25,"EnergyUp")
		goto BrickUp
	BrickUp:
		TNT1 A 0
		TNT1 A 0
		BRK6 ABCDE 2
		goto BrickReady
	EnergyUp:
		BRK1 ABCDEF 2
	RealReady:
		TNT1 A 0 
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		BRK2 ABCDE 3 a_weaponready
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		BRK2 EDCBAFGH 3 a_weaponready
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		BRK2 HGF 3 a_weaponready
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		loop
	BrickReady:
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		BRK6 E 1 a_weaponready
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "BrickRestore")
		loop
	BrickRestore:
		BRK6 CBA 2
		BRK7 BA 2 a_weaponready
		Goto ready
	deselect:
		TNT1 A 0
		TNT1 A 0 a_jumpifhealthlower (1, "deadlower")
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "EnergyLower")
		BRK6 CBA 2
		BRK7 BA 2
		TNT1 A 0 a_playsound ("brickbook/holster",0)
		goto Holster
	EnergyLower:
		BRK4 EDCBA 2
		BRK5 ABCDE 2
		TNT1 A 0 a_playsound ("brickbook/holster",0)
	holster:
		TNT1 A 0
		TNT1 A 0 a_jumpifinventory ("IAmTechMonk",1,"VisorSwapAway")
		Goto Lowering
	VisorSwapAway:
		TNT1 A 0
		TNT1 A 0 a_takeinventory ("ArtiPainTimer",9999)
		TNT1 A 0 a_giveinventory ("ArtiPainTimer",40)
	Lowering:
		TNT1 A 1 a_lower
		TNT1 A 0 a_takeinventory ("secretaction", 99)
		TNT1 AAAA 0 a_lower
		loop
	deadlower:
		TNT1 A 0
		TNT1 A 0
		TNT1 AAAAAAAAAAAAA 0 a_lower
		TNT1 A 1 a_lower
		wait		
	fire:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "WallCast")
	WeakBrick:
		TNT1 A 0
		BRK6 FGHI 1
		BRK6 JKLM 2
		TNT1 A 0 a_playsound ("brickbook/brickthrow",0)
		ZKV2 F 1 a_firecustommissile ("normalbrick")
		ZKV2 GHI 2
		TNT1 A 3
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "EnergyUp")
		BRK7 AB 2
		TNT1 A 0 a_refire
		Goto BrickUp
	Wallcast:
		TNT1 A 0
		TNT1 A 0 a_playsound ("BrickBook/WallCharge",0)
		BRK3 ABCDEFGHI 1
		BRK3 I 3
		BRK3 JK 2
		BRK3 L 2
		TNT1 A 0 a_takeinventory ("CrateEnergy",25)
		TNT1 A 0 a_firecustommissile ("wallglyph")
		TNT1 A 0 a_playsound ("BrickBook/WallCast",0)
		BRK3 M 2 a_firecustommissile ("brickwall")
		BRK3 NOPQ 2
		BRK3 I 3
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "BookReset")
		goto BrickUp
	BookReset:
		TNT1 A 0
		BRK4 ABCDEF 2
		goto realready
		
	Altfire:
		TNT1 A 0
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "PortalCast")
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "BrickRestore")
		BRK6 E 20 a_weaponready 
		TNT1 A 0 a_jumpifinventory ("secretaction",1,"FakeReload")
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "BrickRestore")
		goto BrickReady
	PortalCast:
		TNT1 A 0
		TNT1 A 0 a_playsound ("Brickbook/PortalCharge",0)
		BRK3 ABCDEFGHI 1
		BRK3 I 3
		TNT1 A 0 a_quake (1,32,0,20,"silence")
		BRK8 ABCDEFGHH 2
		BRK8 I 1
		TNT1 A 0 a_takeinventory ("CrateEnergy",25)
		TNT1 A 0 a_playsound ("Brickbook/PortalCast",0)
		BRK8 J 2 a_firecustommissile ("BrickPortal")
		BRK8 KLMNOPQRST 2
		TNT1 A 0 a_jumpifinventory ("CrateEnergy", 25, "BookReset")
		goto BrickUp
		


	FakeReload:
		TNT1 A 4
		CHUG ABCDEF 2
		CHUG F 3
		CHUG GHIJKL 2
		CHUG LNLNMLMN 2
		CHUG O 2 A_Quake(1, 5, 0, 32,"Silence")
		TNT1 A 0 a_playsound ("brickbook/bottletop",0)
		CHUG O 2 A_Quake(2, 5, 0, 32,"Silence")
		CHUG PQRS 1
		TNT1 A 8
		CHUG TUVWXYZ 2
		CHU1 ABBCC 2
		TNT1 A 0 a_playsound ("brickbook/chug",0)		
		CHU1 C 3 offset (0,38)
		CHU1 C 3 offset (0,40)
		CHU1 C 3 offset (0,34)
		CHU1 C 3 offset (0,32)
		CHU1 C 20
		TNT1 A 0 a_playsound ("brickbook/chug",0)		
		CHU1 C 3 offset (0,38)
		CHU1 C 3 offset (0,40)
		CHU1 C 3 offset (0,34)
		CHU1 C 3 offset (0,32)
		CHU1 C 20
		TNT1 A 0 a_playsound ("brickbook/chug",0)		
		CHU1 C 3 offset (0,38)
		CHU1 C 3 offset (0,40)
		CHU1 C 3 offset (0,34)
		CHU1 C 3 offset (0,32)
		CHU1 C 20
		CHU1 C 1 offset (0,36)
		CHU1 C 1 offset (0,42)
		CHU1 C 1 offset (0,50)
		CHU1 C 2 offset (0,60)
		CHU1 C 2 offset (0,70)
		TNT1 A 10 offset (0,32)
		TNT1 A 0 a_jump (50,"belchdone")
		TNT1 A 10
		CHU1 D 1 
		CHU1 EF 1
		TNT1 A 0 a_playsound ("ZharkyFist",0)
		ZKV2 F 1 a_firecustommissile ("Emptybottle")
		ZKV2 GHI 2
		TNT1 A 12
		goto ready
	BelchDone:
		TNT1 A 1 
		TNT1 A 0 a_playsound ("meatball/belch",0)
		TNT1 A 0 A_Quake(3, 15, 0, 32,"Silence")
		TNT1 A 10 offset (0,32)
		CHU1 D 1 
		CHU1 EF 1
		TNT1 A 0 a_playsound ("ZharkyFist",0)
		ZKV2 F 1 a_firecustommissile ("Emptybottle")
		ZKV2 GHI 2
		TNT1 A 12
		goto ready
	}
}


actor normalbrick
{
	Radius 7
	Height 9
	scale 0.15
	Speed 35
	+bright
	+thruspecies
	species "player"
	Damage (40)
	Projectile
	gravity 1.30
	-NOGRAVITY
	+doombounce
	BounceCount 2
	projectilekickback 1000
	seesound "brickbook/brickbounce"
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 A_PlaySound("silence", CHAN_VOICE)
		TNT1 A 0 thrustthingz (0,10,0,1)
	fly:
		CYTB ABCD 2
		loop
	xdeath:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_playsound ("brickbook/brickhit",0)
		TNT1 A 0 a_playsound ("brickbook/brickbreak",0,0.8,0,1.5)
		TNT1 A 0 a_spawnitem ("dedbrick")
		TNT1 AA 0 A_SpawnItemEx("brickshrapnel",0,0,0,random(-20,20),random(-20,20),random(5,10),random(0,359),32)
		stop				
	death:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_spawnitem ("dedbrick")
		TNT1 A 0 a_playsound ("brickbook/brickbreak",0,0.8,0,1.5)
		TNT1 AA 0 A_SpawnItemEx("brickshrapnel",0,0,0,random(-20,20),random(-20,20),random(5,10),random(0,359),32)
		stop		
	}
}

actor PortalBrick : NormalBrick
{
	+NOGRAVITY
	-BOUNCEONWALLS
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 1 a_playsound ("brickbook/brickthrow",CHAN_VOICE,0.20,0,1.5)
	fly:
		CYTB ABCD 2
		CYTB ABCD 2
		CYTB ABCD 2
		CYTB ABCD 2
		CYTB ABCD 2
		TNT1 A 0 a_changeflag ("NOGRAVITY",0)
		goto FallingLoop
	FallingLoop:
		CYTB ABCD 2
		Loop
	}
}

actor brickwall
{
	projectile
	+ripper
	+bloodlessimpact
	+floorhugger
	+thruspecies
	+bright
	+dontblast
	+nobossrip
	+FORCERADIUSDMG
	+NODAMAGETHRUST
	Radius 20
	Height 40
	mass 99999
	Speed 20
	Damage (30)
	species "player"
	alpha 0.60
	Scale 1
	Decal RailScorchLower
	states
	{
	spawn:	
		TNT1 A 0
		TNT1 A 0 a_playsound ("brickbook/wallslide", 6,1,1,0.7)
	sliding:
		TNT1 A 0 A_SpawnItemEx("NormalBrick",0,0,0,random(-10,10),random(-10,10),random(5,10),random(0,359),32)
		TNT1 A 0 A_SpawnItemEx("NormalBrick",0,0,0,random(-10,10),random(-10,10),random(8,15),random(0,359),32)
		TNT1 AA 0 a_spawnitemex ("wallparticle", Frandom(-30,30),Frandom(-30,30))
		TNT1 A 0 a_spawnitemex ("BrickShield",20,0,40)
		TNT1 A 0 a_radiusthrust (600,100)
		VXWA A 1
		TNT1 A 0 a_spawnitemex ("BrickShield",20,0,40)
		TNT1 A 0 a_spawnitemex ("wallparticle", Frandom(-30,30),Frandom(-30,30))
		TNT1 AA 0 A_SpawnItemEx("brickshrapnel",0,0,0,random(-20,20),random(-20,20),random(5,10),random(0,359),32)
		TNT1 A 0 radius_quake (2,6,0,15,0)
		loop
	death:
		TNT1 A 0
		TNT1 A 0 a_stopsound (6)
		TNT1 A 0 a_playsound ("Cyclops/rocketboom",0)
		TNT1 A 0 a_playsound ("brickbook/wallexplode",0,1,0,0.60)
		TNT1 A 0 radius_quake (3,6,0,15,0)
		TNT1 A 0 a_explode (1600,80,0,1,80)
		TNT1 A 0 a_explode (680,150,0,1,100)
		TNT1 AAAAAA 0 A_SpawnItemEx("normalbrick",0,0,0,random(-40,40),random(-40,40),random(10,20),random(0,359),32)
		TNT1 AAAAAAAAAAAA 0 A_SpawnItemEx("BrickShrapnel",0,0,0,random(-40,40),random(-40,40),random(10,20),random(0,359),32)
		TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("lavalazersmoke",0,0,3,random(-8,8),random(-10,10),random(4,10),random(0,359),32)
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("lavalazersmoke2",0,0,3,random(-8,8),random(-10,10),random(4,10),random(0,359),32)
		TNT1 A 0 a_spawnitemex ("wallsmoke")
		stop
	}
}


actor BrickShield
{
	projectile
	+noblood
	+shootable
	+notimefreeze
	+ripper
	+bloodlessimpact
	+thruspecies
	+notargetswitch
	+NORADIUSDMG
	+PAINLESS
	+DONTRIP
	+hexenbounce
	-bloodsplatter
	-noblockmap
	-ACTIVATEIMPACT
	painchance 255
	species "Player"
	radius 24 
	height 50
	speed 40
	mass 1
	damage (0)
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 1
		goto blockend
	blockend:
		TNT1 A 0
		TNT1 A 1 
		stop
	death:
		TNT1 A 0
		TNT1 A 1
		stop
	pain:
		TNT1 A 0 Radius_Quake (1,8,0,20,0)
		TNT1 A 1
		stop
	Pain.Linked:
		TNT1 A 1
		stop
	Pain.LinkedBomb:
		TNT1 A 0
		TNT1 A 0 Radius_Quake (2,8,0,20,0)
		TNT1 A 1
		stop

	}
}

actor BrickPortal
{
	Projectile
	Radius 7
	Height 9
	scale 1
	Speed 20
	+bright
	+NOINTERACTION
	+thruspecies
	species "player"
	Damage 0
	gravity 1.30
	reactiontime 80
	
	var int user_britch;
	states
	{
	Spawn:
		GLPH A 1
		GLPH A 1 A_SetAngle ((CallACS("DupeMasterAngle") / 65536.0) * 360.0)
		GLPH A 2
		TNT1 A 0 a_stop
		TNT1 A 0 a_playsound ("BrickBook/PortalHum",CHAN_VOICE,1,1,1.5)
		GLPH B 1 
	FirstShot:
		GLPH C 1
		GLPH D 1 A_CustomMissile ("PortalBrick", frandom(-10,10), frandom(-10,10), frandom(-4,4), CMF_AIMDIRECTION | CMF_OFFSETPITCH, -((CallACS("DupeMasterPitch") / 65536.0) * 360.0)+Frandom(-5,5))
		TNT1 A 0 A_SetUservar("user_britch", -((CallACS("DupeMasterPitch") / 65536.0) * 360.0))
		GLPH E 2
	Shooting:
		GLPH H 2
		GLPH I 2  A_CustomMissile ("PortalBrick", frandom(-10,10), frandom(-10,10), frandom(-4,4), CMF_AIMDIRECTION | CMF_OFFSETPITCH, user_britch +Frandom(-5,5))
		GLPH J 2 
		GLPH G 2  A_CustomMissile ("PortalBrick", frandom(-10,10), frandom(-10,10), frandom(-4,4), CMF_AIMDIRECTION | CMF_OFFSETPITCH, user_britch +Frandom(-5,5))
		TNT1 A 0 a_countdown
		loop
	death:
		GLPH I 1
		TNT1 A 0 a_playsound ("BrickBook/PortalEnd",CHAN_VOICE,1,0,1.5)
		GLPH ICBA 2
		stop
	}
}

actor EmptyBottle
{
    +notimefreeze
	+BLOODSPLATTER
	+FORCEXYBILLBOARD	
	+thruspecies
	+bright
	+forcepain
	species "Player"
	Radius 11
	Height 8
	Speed 40
	Damage (120)
	Projectile
	scale 0.20
	deathsound "Brickbook/bottlebreak"
	states
	{
	spawn:
		EBTL ABCDEFGH 1
		TNT1 A 0 a_changeflag ("NOGRAVITY",0)
		goto falling
	falling:
		EBTL ABCDEFGH 1
		loop
	death:
		TNT1 A 0 a_playsound ("BMicebeam/shardmiss",0,1,0,0.50)
		TNT1 AAAAAAAAA 0 a_spawnitemex ("daggershard",0,0,frandom(1,3),random(-8,8),random(-8,8),frandom(3,6)) 
		SHEX ABCDE 2 Bright
		stop
	}
}

actor daggershard
{
	projectile
	-NOGRAVITY
	+thruactors
	damage (0)
	gravity 1.2
	+hexenbounce
	Bouncecount 2
	bouncefactor 0.80
	+bright
	renderstyle add
	scale 0.40
	states
	{
	Spawn:
		CTRP ABCDEF 2
		loop
	death:
		TNT1 A 0
		TNT1 A 1
		stop
	}
}


ACTOR Brickshrapnel
{
	Damage (15)
	Speed 12
	Radius 6
	Height 3
	Scale 0.5
	Gravity 0.7
	PROJECTILE
	-NOGRAVITY
	+DONTBLAST
	+bright
	+thruspecies
	+hexenbounce
	BounceCount 4
	seesound "brickbook/stonebounce"
	species "player"
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_playsound ("silence",CHAN_VOICE)
	rollin:
		ESTN A 1	  
		Loop
	Death:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 a_playsound ("brickbook/stonebreak",0,0.8,0,1.5)
		ESTN B 3
		TNT1 AAA 0 A_SpawnItemEx("Brickdebris",0,0,3,random(-1,1),random(-1,1),random(2,4),random(0,359),32)
		Stop
	}
}


ACTOR Brickdebris
{
	Speed 8
	Radius 2
	Height 2
	Scale 0.2
	Gravity 0.6
	PROJECTILE
	-NOGRAVITY
	+bright
	+DONTBLAST
	+thruspecies
	species "player"
	States
	{
	Spawn:
		ESTN C 1	  
		Loop
	Death:
		TNT1 A 0
		Stop
	}
}


actor dedbrick
{
	+NOBLOCKMAP
	+DONTSPLASH
	+nogravity
	+dontfall
	+NOTELEPORT
	+bright
	+thruactors
	+clientsideonly
	+thruspecies
	species "player"
	scale 0.50
	States
	{
	spawn: 
		ESTN AB 2
		goto death
	death:
		TNT1 A 0
		TNT1 A 0
		TNT1 AAA 0 A_SpawnItemEx("Brickdebris",0,0,3,random(-1,1),random(-1,1),random(2,4),random(0,359),32)
		TNT1 AA 0 A_SpawnItemEx("lavalazersmoke",0,0,3,random(-1,1),random(-1,1),random(0,1),random(0,359),32)
		stop
	}
}

actor wallsmoke
{
	+NOBLOCKMAP
	+DONTSPLASH
	+nogravity
	+dontfall
	+NOTELEPORT
	+bright
	+thruactors
	+clientsideonly
	+thruspecies
	RenderStyle add
	alpha 0.60
	species "player"
	scale 3
	States
	{
	spawn:
		WLXP ABCDEFGHI 2
		WLXP JKLMNOP 3 a_fadeout (0.05)
		stop
	death:
		TNT1 A 0
		TNT1 A 0
		stop
	}
}


actor BrickGlyph
{
	+dontblast
	+notimefreeze
	+nointeraction
	+clientsideonly
	projectile
    +FORCEXYBILLBOARD	
	+LOOKALLAROUND
	+bright
	radius 2
	speed 40
    Scale 1
	renderstyle add
	alpha 0.50
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 1
		TNT1 A 0 A_stop
		GLPH A 2
		GLPH B 3
		GLPH B 1 a_fadeout (0.10)
		wait
	death:
		TNT1 A 0
		TNT1 A 1
		stop
	}
}


actor WallGlyph : brickglyph
{
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 1
		TNT1 A 0 A_stop
		GLPH AB 2
	spin:
		GLPH CDEF 2
		TNT1 A 0 a_fadeout (0.10)
		loop
	}
}


//Used to measure how much charge the player is building 
actor BrickMana : ammo
{
  Inventory.PickupMessage "Brick mana (you shouldn't find this either, you sneaky bastard)"
  Inventory.Amount 1
  Inventory.MaxAmount 9
  Inventory.Icon "BAL1A0"
  Ammo.BackpackAmount 0
  Ammo.BackpackMaxAmount 0
  states
  {
  Spawn:
    BAL1 A -1
    stop
  }
}


actor brickstack : inventory
{inventory.maxamount 5}

actor javelinstack : inventory
{inventory.maxamount 5}

actor Wallstack : inventory
{inventory.maxamount 1}
