/////////////////////////////////////////
//        HELLMARK TYRANT NG-01        //
/////////////////////////////////////////

Actor KingClone 31005
{
//$Category MM8BDM-Monsters (Custom)
//$Title Hellmark Tyrant NG-01
//$Sprite D035B8B2
Tag "Hellmark Tyrant NG-01"
Translation "72:72=180:180", "192:192=91:91", "198:198=3:3", "210:210=87:87"
MONSTER
Species "BossMonster"
BloodType "MonsterRipperProtect_Helper"
//+NOBLOOD
+FLOORCLIP
-NOINFIGHTING
+DOHARMSPECIES
+DROPOFF
+JUMPDOWN
+BOSS
Health 2000
Radius 20
Height 68
Speed 1 // 8
PainChance 200
PainChance "WindStorm", 0
PainChance "GravityHold", 0
PainChance "ConcreteShot", 0
PainChance "TornadoBlow", 0
PainChance "BlackHoleBomb", 0
PainChance "TimeStopper", 256
DamageFactor "Dummy", 0.0
SeeSound "misc/bombcount"
PainSound "monster/mm6pain"
ActiveSound "misc/repairing"
Obituary "$OB_KINGCLONE"
Mass 9999
Scale 2.5
States
{
Spawn:
KING A 0 NoDelay A_Stop
KING A 0 A_TakeInventory("CutterFlag",1)
KING A 0 ACS_NamedExecuteAlways("Monster_PassivePain",0)
KING A 0 A_SpawnItemEx("MonsterHitbox20_68")
KING A 10 A_Look
Goto Spawn+4

FirstSee:
KING A 0 A_TakeInventory("CutterFlag",1)
KING A 0 ACS_NamedExecuteAlways("Monster_PassivePain",0)
KING A 0 Thing_SetTranslation(0,30501) //ALLRED
KING A 2 Bright
KING A 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING A 0 A_GiveInventory("CutterFlag",1)
Goto SeeCheck

See:
KING "#" 0 A_JumpIfInventory("CutterFlag",1,1)
Goto FirstSee
SeeCheck:
KING "#" 0 A_JumpIfInventory("IceWaveAmmo",3,"SeeE")
KING "#" 0 A_JumpIfInventory("IceWaveAmmo",2,"SeeD")
KING "#" 0 A_JumpIfInventory("IceWaveAmmo",1,"SeeC")
SeeB:
KING B 0 A_GiveInventory("IceWaveAmmo",1)
Goto SeeLoop
SeeC:
KING C 0 A_GiveInventory("IceWaveAmmo",1)
Goto SeeLoop
SeeD:
KING D 0 A_GiveInventory("IceWaveAmmo",1)
Goto SeeLoop
SeeE:
KING E 0 A_TakeInventory("IceWaveAmmo",99)
Goto SeeLoop

SeeLoopReset:
KING "#" 0 A_TakeInventory("IceWallAmmo",99)
Goto SeeCheck

SeeLoop:
KING "#" 0 A_JumpIfInventory("IceWallAmmo",6,"SeeLoopReset")
KING "#" 1 A_Chase("","")
KING "#" 0 A_ChangeVelocity(4,0,momz,3)
KING "#" 0 A_GiveInventory("IceWallAmmo",1)
KING "#" 0 A_GiveInventory("BusterGiven",1)
KING "#" 0 A_JumpIfInventory("BusterGiven",64,"MissileLOSCheck")
KING "#" 0 A_JumpIf(CallACS("IsTargetInGame")==0,"Spawn")
Goto SeeLoop

MissileLOSCheck:
KING A 0 A_JumpIfTargetInLOS("PhantomSlash")
KING A 0 A_TakeInventory("BusterGiven",99)
Goto SeeLoop
PhantomSlash:
KING A 0 A_Stop
KING A 0 A_GiveInventory("FlashStopperAmmo",1)
KING A 0 A_TakeInventory("BusterGiven",99)
KING A 0 A_PlaySoundEx("misc/fakereloadshort","Weapon")
KING A 0 Thing_SetTranslation(0,30504) //MISSILEFLASH
KING A 2
KING A 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING A 6 A_FaceTarget
KING A 0 A_Jump(192,"PhantomSlashContinue")
KING A 0 A_Jump(256,3)
KING A 0 A_ChangeVelocity(0,20,5,3)
KING A 0 A_Jump(128,2)
KING A 0 A_ChangeVelocity(0,-20,5,3)
PhantomSlashContinue:
KING FFFFFFGG 1 A_Turn(45)
KING F 0 Thing_SetTranslation(0,30504) //MISSILEFLASH
KING F 0 A_PlaySoundEx("weapon/chargekick","Weapon")
KING F 0 A_CustomMissile("KingClonePhantomSlash0",38,0,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash8",38,-6,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash8",38,6,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash7",38,-12,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash7",38,12,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash6",38,-18,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash6",38,18,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash5",38,-24,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash5",38,24,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash4",38,-30,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash4",38,30,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash3",38,-36,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash3",38,36,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash2",38,-42,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash2",38,42,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash1",38,-48,0,CMF_AIMOFFSET)
KING F 0 A_CustomMissile("KingClonePhantomSlash1",38,48,0,CMF_AIMOFFSET)
KING GG 1 Bright A_Turn(45)
KING F 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING F 0 A_TakeInventory("FlashStopperAmmo",99)
KING FF 2
Goto See

UnholySeal:
KINC A 0 A_Stop
KINC A 1 A_GiveInventory("StarCrashAmmo",1)
KINC A 0 A_TakeInventory("StarCrashAmmo",99)
KINC A 0 A_TakeInventory("JunkShieldAmmo",99)
KINC A 0 A_TakeInventory("TopSpinAmmo",99)
KING W 2 A_FaceTarget
KING W 0 A_PlaySoundEx("weapon/mirrorabsorb","Weapon")
KINC DDEEDDEEDDEEDEDEDE 1 A_SpawnItemEx("KingCloneAura1")
KINC DE 1 Bright A_SpawnItemEx("KingCloneAura1")
KINC D 0 A_PlaySoundEx("misc/kingblast","Weapon")
KINC D 0 A_FaceTarget
KINC DDDDDDDDDDDD 0 A_CustomMissile("KingCloneUnholySeal",38)
KINC D 0 Thing_SetTranslation(0,30501) //ALLRED
KINC DDDDDDDDDDDD 0 A_SpawnItemEx("TimeStopGFX",random(32,64),0,random(4,96),0,0,0,random(0, 359))
KINC DE 1 Bright A_SpawnItemEx("KingCloneAura2",0,0,-16)
KINC D 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KINC DEDEDEDEDDEEDDEE 1 A_SpawnItemEx("KingCloneAura1")
KINC A 0 A_ChangeFlag("INVULNERABLE",false)
KING W 4
Goto See

GuardStart:
KINC A 0 A_Stop
//KINC A 0 A_ChangeFlag("INVULNERABLE",true)
KINC A 0 A_SpawnItemEx("KingCloneGuardShield",28)
GuardLoop:
KINC A 0 A_JumpIfInventory("TopSpinAmmo",5,"UnholySeal")
KINC A 0 A_JumpIfInventory("JunkShieldAmmo",10,"GuardDodge")
KINC AAA 1 A_FaceTarget
KINC A 0 A_GiveInventory("JunkShieldAmmo",1)
Loop
GuardDodge:
KINC A 0 A_JumpIfInventory("TopSpinAmmo",5,"UnholySeal")
KINC A 2
KINC A 0 A_PlaySoundEx("misc/darkleap","Body")
KINC A 0 A_Jump(128,3)
KINC A 0 A_ChangeVelocity(0,30,5,3)
KINC A 0 A_Jump(256,2)
KINC A 0 A_ChangeVelocity(0,-30,5,3)
GuardDodgeLoop:
KINC C 0 A_JumpIfInventory("TopSpinAmmo",5,"UnholySeal")
KINC C 0 A_FaceTarget
KINC C 1 A_SpawnItemEx("KingCloneDodgeFX")
KINC C 0 A_CheckFloor("GuardDodgeEnd")
Loop
GuardDodgeEnd:
KINC A 0 A_PlaySoundEx("monster/mm6land","Body")
KINC A 4 A_Stop
Goto GuardEnd
GuardEnd:
//KINC A 0 A_ChangeFlag("INVULNERABLE",false)
KINC A 1 A_GiveInventory("StarCrashAmmo",1)
KINC A 0 A_TakeInventory("JunkShieldAmmo",99)
KINC A 0 A_TakeInventory("StarCrashAmmo",99)
Goto See

Pain:
KING H 0 A_Stop
Pain.WindStorm:
Pain.GravityHold:
Pain.ConcreteShot:
Pain.TornadoBlow:
Pain.BlackHoleBomb:
KING W 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING W 0 A_JumpIfInventory("TopSpinAmmo",5,"UnholySeal")
KING W 0 A_JumpIfInventory("FlashStopperAmmo",1,"StunnedStart")
KING W 0 A_PlaySoundEx("misc/darkthrow","Body")
//KING W 0 A_ChangeFlag("INVULNERABLE",true)
KING W 0 A_Pain
KING W 0 A_SpawnItemEx("KingCloneGuardShieldFX",28)
KING WWWWW 1
Goto GuardStart

Pain.TimeStopper:
KING H 0 A_Stop
KING H 0 A_TakeInventory("TopSpinAmmo",99)
KING H 0 A_TakeInventory("JunkShieldAmmo",99)
KING H 0 A_TakeInventory("FlashStopperAmmo",99)
KING H 0 A_TakeInventory("StarCrashAmmo",99)
KING H 0 A_TakeInventory("BusterGiven",99)
KING H 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING H 0 A_ChangeFlag("NOPAIN",true)
KING "########################################################################################" 1 A_SpawnItemEx("TimeStopGFX",random(8,56),0,random(0,72),0,0,0,random(0,359),0,80)
KING H 0 A_ChangeFlag("NOPAIN",false)
Goto See

StunnedStart:
KING H 0 A_PlaySoundEx("weapon/coilfire2","Body")
KING H 0 A_FaceTarget
KING H 0 A_ChangeVelocity(-15,0,8,3)
KING H 0 A_ChangeFlag("NOPAIN",true)
KING H 2
KING H 0 A_PlaySoundEx("misc/trainwhistle","Weapon")
StunnedLoop:
KING H 0 A_FaceTarget
KING H 0 A_SpawnItemEx("KingExplode",28+random(-15,15),-28+random(-15,15),40+random(-15,15),0,0,0,0,SXF_NOCHECKPOSITION)
KING H 1 A_CheckFloor("StunnedContinue")
KING H 1 A_CheckFloor("StunnedContinue")
KING H 1 A_CheckFloor("StunnedContinue")
KING H 1 A_CheckFloor("StunnedContinue")
KING H 1 A_CheckFloor("StunnedContinue")
Loop
StunnedContinue:
KING H 0 A_Stop
KING HHVR 4
KINP NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN 1 A_SpawnItemEx("KingCloneStunnedFX",0,0,4,frandom(-5,5),0,frandom(-5,5),random(0,359))
KING VVVVVV 1 A_SpawnItemEx("KingCloneStunnedFX",0,0,4,frandom(-5,5),0,frandom(-5,5),random(0,359))
KING SSSSSSSSSSSSSSSSS 1 A_SpawnItemEx("KingCloneStunnedFX2",0,0,4,frandom(-5,5),0,frandom(-5,5),random(0,359))
KING N 0 A_ChangeFlag("INVULNERABLE",true)
KING Q 0 Thing_SetTranslation(0,30503) //ALLWHITE
KING Q 2
KING Q 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING Q 0 A_PlaySoundEx("misc/terraclick","Body")
KING Q 16
KING N 0 A_PlaySoundEx("misc/darkleap","Body")
KING N 0 A_ChangeVelocity(random(-15,15),random(-15,15),16,3)
StunnedLoop2:
KING N 0 A_FaceTarget
KING N 1 A_SpawnItemEx("KingCloneRecoverFX")
KING N 0 A_CheckFloor("StunnedEnd")
Loop
StunnedEnd:
KING A 0 A_PlaySoundEx("monster/mm6land","Body")
KING A 0 A_ChangeFlag("INVULNERABLE",false)
KING A 0 A_ChangeFlag("NOPAIN",false)
KING A 0 A_Stop
KING A 0 A_TakeInventory("FlashStopperAmmo",99)
KING A 4
Goto See

Death:
XDeath:
FAKM H 0 A_Stop
FAKM H 0 A_FaceTarget
FAKM H 0 A_NoBlocking
KING H 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING H 0 A_PlaySound("misc/gamma2pain",CHAN_BODY,1.0,0,0.0)
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,30503) //ALLWHITE
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,30503) //ALLWHITE
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,30503) //ALLWHITE
KING H 2 Bright
KING H 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
KING H 2 Bright
KING H 0 A_PlaySound("weapon/drillexplode",CHAN_AUTO,1.0,0,0.0)
KING H 0 A_SpawnItemEx("ExplosionEffect2",random(-32,32),random(-32,32),random(0,64))
KING HZHZ 3 A_SetTranslucent(0.9)
KING H 0 A_PlaySound("weapon/drillexplode",CHAN_AUTO,1.0,0,0.0)
KING H 0 A_SpawnItemEx("ExplosionEffect2",random(-32,32),random(-32,32),random(0,64))
KING HZHZ 3 A_SetTranslucent(0.8)
KING H 0 A_PlaySound("weapon/drillexplode",CHAN_AUTO,1.0,0,0.0)
KING H 0 A_SpawnItemEx("ExplosionEffect2",random(-32,32),random(-32,32),random(0,64))
KING HZHZ 3 A_SetTranslucent(0.7)
KING H 0 A_PlaySound("weapon/drillexplode",CHAN_AUTO,1.0,0,0.0)
KING H 0 A_SpawnItemEx("ExplosionEffect2",random(-32,32),random(-32,32),random(0,64))
KING HZHZ 3 A_SetTranslucent(0.6)
KING H 0 A_PlaySound("misc/devildeath",CHAN_AUTO,1.0,0,0.0)
KING H 0 A_SpawnItemEx("FakeDeathFX",0,0,32,0,0,0,0,1)
KING HZHZ 3 A_SetTranslucent(0.0)
TNT1 H 0 A_JumpIf(CallACS("Monster_CanDropWeapon"),4)
TNT1 H 0 A_Jump(256,2)
TNT1 H 0 A_JumpIf(True,2)
TNT1 H 0 ACS_NamedExecuteWithResult("Monster_WeaponDrop",4) //Devil Cannon
TNT1 A 5
Stop
}
}

actor KingClonePhantomSlashA : FastProjectile
{
Translation "0:255=4:4"
Damagetype "Dummy"
Damage (12)
MissileType "KingClonePhantomSlashFXA"
MissileHeight 8
Radius 12
Height 8
Speed 70
RenderStyle Add
Alpha 0.75
Scale 2
Mass 0
States
{
Spawn:
TNT1 A 0 NoDelay A_ScaleVelocity(0.0)
TNT1 A 0 A_SetTics(Mass)
TNT1 A 0 A_SetDamageType("Buster")
TNT1 A 0 A_ScaleVelocity(1.0)
Goto SpawnLoop

SpawnLoop:
CKIC E 1
Loop
	
Death:
TNT1 A 0
stop
}
}

actor KingClonePhantomSlashFXA : KingClonePhantomSlashA 
{ 
Translation "0:255=0:0"
Damage (0) 
RenderStyle Translucent 
Alpha 0.05
States
{
Spawn:
CKIC E 1 NoDelay A_FadeOut(0.01)
Loop
}
}

actor KingClonePhantomSlashB : KingClonePhantomSlashA
{
Damagetype "Buster"
Damage (5)
MissileType "KingClonePhantomSlashFXB"
Mass 0
Scale 1.75
States
{
Spawn:
TNT1 A 0 NoDelay A_ScaleVelocity(0.0)
CKIC D 1 A_SetTics(Mass)
TNT1 A 0 A_SetDamageType("Dummy")
Stop
}
}

actor KingClonePhantomSlashFXB : KingClonePhantomSlashB 
{ 
Translation "0:255=0:0"
Damage (0) 
RenderStyle Translucent 
Alpha 0.05
States
{
Spawn:
CKIC D 1 NoDelay A_FadeOut(0.01)
Loop
}
}

actor KingClonePhantomSlashC : KingClonePhantomSlashB
{
Damage (2)
MissileType "KingClonePhantomSlashFXC"
Scale 2.25
States
{
Spawn:
TNT1 A 0 NoDelay A_ScaleVelocity(0.0)
ICES A 1 A_SetTics(Mass)
TNT1 A 0 A_SetDamageType("Dummy")
Stop
}
}

actor KingClonePhantomSlashFXC : KingClonePhantomSlashC 
{ 
Translation "0:255=0:0"
Damage (0) 
RenderStyle Translucent 
Alpha 0.05
States
{
Spawn:
ICES A 1 NoDelay A_FadeOut(0.01)
Loop
}
}

actor KingClonePhantomSlash0 : KingClonePhantomSlashA { Mass 0 SeeSound "misc/kingchop" }
actor KingClonePhantomSlash1 : KingClonePhantomSlashB { Mass 3 }
actor KingClonePhantomSlash2 : KingClonePhantomSlashB { Mass 6 }
actor KingClonePhantomSlash3 : KingClonePhantomSlashB { Mass 9 }
actor KingClonePhantomSlash4 : KingClonePhantomSlashB { Mass 12 }
actor KingClonePhantomSlash5 : KingClonePhantomSlashC { Mass 15 }
actor KingClonePhantomSlash6 : KingClonePhantomSlashC { Mass 18 }
actor KingClonePhantomSlash7 : KingClonePhantomSlashC { Mass 21 }
actor KingClonePhantomSlash8 : KingClonePhantomSlashC { Mass 24 }

actor KingCloneGuardShield
{
Translation "72:72=180:180", "192:192=91:91", "198:198=3:3", "210:210=87:87"
-SOLID
+SHOOTABLE
+DONTRIP
+NOBLOOD
+NOGRAVITY
+NOTARGETSWITCH
+NODAMAGE
PainChance 256
Scale 2.5
Height 80
Radius 48
States
{
Spawn:
KINC F 0 NoDelay A_JumpIfInTargetInventory("DrillFlag",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("StarCrashAmmo",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("TopSpinAmmo",5,"DeathSuper")
KINC F 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
Loop

Pain:
KINC F 0 Thing_SetTranslation(0,30501) //ALLRED
KINC F 0 A_GiveToTarget("TopSpinAmmo",1)
KINC F 0 A_PlaySoundEx("misc/catchermove","Body")
KINC F 0 A_JumpIfInTargetInventory("DrillFlag",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("StarCrashAmmo",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("TopSpinAmmo",5,"DeathSuper")
KINC F 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
KINC F 0 A_JumpIfInTargetInventory("DrillFlag",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("StarCrashAmmo",1,"Death")
KINC F 0 A_JumpIfInTargetInventory("TopSpinAmmo",5,"DeathSuper")
KINC F 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
KINC F 0 Thing_SetTranslation(0,31005) //KINGCLONEMONSTER
Goto Spawn

Death:
TNT1 A 0
Stop

DeathSuper:
KINC F 0 Thing_SetTranslation(0,30503) //ALLWHITE
KINC F 0 A_PlaySoundEx("weapon/skullcounter","Body")
KINC FFFFFFFFFFFFFFFFFFFFFFF 0 A_SpawnItemEx("FreezeCrackerFX",0,0,48,frandom(-10,10),0,frandom(-5,5),random(0,359))
KINC FF 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
Stop
}
}

actor KingCloneGuardShieldFX : KingCloneGuardShield
{
Translation "0:0=4:4", "72:72=0:0", "192:192=0:0", "198:198=0:0"
-SHOOTABLE
PainChance 0
Renderstyle Add
States
{
Spawn:
KINC F 0 NoDelay A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
KINC FFF 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
KINC F 0 Thing_SetTranslation(0,30503) //ALLWHITE
KINC FF 1 A_Warp(AAPTR_TARGET,28,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
stop
}
}

actor KingCloneDodgeFX : BasicGraphicEffect
{
Translation "0:255=180:180"
Scale 2.5
RenderStyle Add
Alpha 0.15
States
{
Spawn:
KINC C 1 NoDelay A_FadeOut(0.01)
Loop
}
}

actor KingCloneStunnedFX : KingCloneDodgeFX
{
Translation "0:255=4:4"
Alpha 0.20
States
{
Spawn:
KINP N 1 NoDelay A_FadeOut(0.03)
Loop
}
}

actor KingCloneStunnedFX2 : KingCloneDodgeFX
{
Translation "0:255=4:4"
Alpha 0.20
States
{
Spawn:
KING S 1 NoDelay A_FadeOut(0.03)
Loop
}
}

actor KingCloneRecoverFX : KingCloneDodgeFX
{
Alpha 0.15
States
{
Spawn:
KING N 1 NoDelay A_FadeOut(0.01)
Loop
}
}

actor KingCloneAura1
{
Translation "0:255=180:180"
+NOINTERACTION
RenderStyle Add
Scale 2.5
States
{
Spawn:
KINC E 1 NoDelay
KINC E 0 A_SetScale(ScaleX+0.15,ScaleY+0.15)
KINC E 0 A_FadeOut(0.25)
Loop
}
}

actor KingCloneAura2 : KingCloneAura1 
{ 
Translation "0:255=4:4" 
Renderstyle Translucent
Alpha 0.75
Scale 3.5
States
{
Spawn:
KINC E 1 NoDelay
KINC E 0 A_FadeOut(0.05)
Loop
}
}

actor KingCloneUnholySeal
{
PROJECTILE
+SEEKERMISSILE
Height 10
Radius 10
Scale 2.5
Speed 20
damage (2)
DamageType "SparkShock"
Renderstyle Fuzzy
States
{
Spawn:
TNT1 A 0 NoDelay A_SeekerMissile(0,180)
KINC I 2 A_SpawnItemEx("KingCloneUnholySealTrail1")
TNT1 A 0 A_Weave(4,0,4,0)
KINC K 2 A_SpawnItemEx("KingCloneUnholySealTrail2")
TNT1 A 0 A_Weave(4,0,4,0)
loop
}
}

actor KingCloneUnholySealTrail
{
+NOGRAVITY
+NOINTERACTION
renderstyle add
alpha 1.0
+BRIGHT
scale 2
States
{
Spawn:
KINC H 1 NoDelay A_FadeOut(0.1)
loop
}
}

actor KingCloneUnholySealTrail1 : KingCloneUnholySealTrail
{
scale 2.5
States
{
Spawn:
KINC H 1 NoDelay A_FadeOut(0.075)
KINC H 0 A_ChangeVelocity(0,0,0.5,CVF_REPLACE)
KINC H 0 A_SetScale(ScaleX-0.15,ScaleY-0.15)
KINC J 1 A_FadeOut(0.075)
KINC J 0 A_ChangeVelocity(0,0,0.5,CVF_REPLACE)
KINC J 0 A_SetScale(ScaleX-0.15,ScaleY-0.15)
loop
}
}

actor KingCloneUnholySealTrail2 : KingCloneUnholySealTrail
{
scale 2.5
States
{
Spawn:
KINC J 1 NoDelay A_FadeOut(0.075)
KINC J 0 A_ChangeVelocity(0,0,0.5,CVF_REPLACE)
KINC J 0 A_SetScale(ScaleX-0.15,ScaleY-0.15)
KINC I 1 A_FadeOut(0.075)
KINC I 0 A_ChangeVelocity(0,0,0.5,CVF_REPLACE)
KINC I 0 A_SetScale(ScaleX-0.15,ScaleY-0.15)
loop
}
}