;
; MAKEFAST DX
; 3.5MHZ PATCH FOR C64 MODE OF C64DX
; WRITTEN BY STEPHAN KLEINERT, (C) 1996
;

ORG 679                      ; RS 232 BUFFER
                             ;

JSR STARTFAST                ; ACTIVATE 3.5MHZ
JMP WEDGE                    ; INSTALL WEDGE

:OLD
W 0                          ; ROOM TO STORE OLD LOAD VECTOR

:MESSAGE
B "!FAST!",13,0              ; INIT MESSAGE

:WEDGE
LDX $0330                    ; GET OLD LOAD VECTOR
LDY $0331
STX OLD                      ; AND STORE IT
STY OLD+1
LDX #<PATCH                  ; GET PATCH START ADDRESS
LDY #>PATCH
STX $0330                    ; AND STORE IT TO LOAD VECTOR
STY $0331

LDY #$00
:DISP
LDA MESSAGE,Y                ; DISPLAY INIT MESSAGE
BEQ ENDE
JSR $FFD2
INY
JMP DISP

:ENDE
RTS                          ; FINITO BENITO

:PATCH
JSR OLDR                     ; DO OLD ROUTINE
PHA
TXA                          ; SAVE REGISTERS
PHA                          ; (THE C65 CPU HAS BETTER OPCODES FOR DOING THIS,
TYA                          ; BUT I'M MUCH TOO LAZY TO WRITE THE MACROS)
PHA
JSR STARTFAST                ; START FAST MODE
PLA
TAY
PLA                          ; GET REGISTERS AGAIN (SIGH)
TAX
PLA
RTS

:STARTFAST
LDX #165                     ; WRITE KEY CODE TO ACTIVATE VIC III MODE
LDY #150                     ;
STX 53295                    ; INTO KEY REGISTER
STY 53295
LDX #%01000000               ; 53297, BIT 6 = 3.5 MHZ PROCESSOR CLOCK
STX 53297                    ; ... AND PULL EEL.
RTS

:OLDR
JMP (OLD)                    ; DO OLD LOAD ROUTINE